Shell Programming and Scripting

     # BLOCK 1
     # FNR==NR is true when dealing with the FIRST file - file with ranges
FNR==NR {
      #    save the customer name from the SECOND field in the array 'cust' indexed
      #    by the record/line number
  cust[FNR]=$2
      #    split the LAST [$NF] field [range specification] by '-' and save the results
      #    in an array 't'
  split($NF, t, "-")
      #    save the LOW limit of the range 't[1]' in an array 'custLow' indexed by
      #    currect record/line number
  custLow[FNR]=t[1]
      #    do the same as above for the HIGH limit in the range
  custHigh[FNR]=t[2]

      #    save the currect record/line number in a variable
  maxType=FNR
      #    jump to the NEXT record/line
  next
}

FNR == 1 { FS=","; $0=$0 }

      #    BLOCK 2
      #    Here we're dealing with the OTHER file specified on the command line
      #    fileWITHdata.txt - line by line.
{
  printf("\tDEBUG:: num->[%s]\n", $2)
      #    iterate from '1' to the maxType - 'maxType' was the number of
      #    lines/records processed in 'BLOCK 1' - number of 'range' specifications.
  for(i=1; i <= maxType; i++) {
       #    determine if the current number 'num' falls within one of the range arrays
       #    populated in 'BLOCK 1'
  if ( $2 >= custLow[i] && $2 <= custHigh[i] )
          #    If it does, increment the number the value in the array 'final' which is
          #    indexed by the cutomerName - the csutomerName was saved in 'BLOCK 1'
          #    and was indexed by the record/line number which is our iterator in this
          #    surrounding 'for' loop.
      final[cust[i]]++
  }
}

         #   END of processing block - this gets executed when ALL the files have been
         #   processed
END {
         #   iterate through ALL the indecies 'i' in array 'final' - 'i' contains the name of
         #   a customer. The value of a given array cell is the NUMBER of times a
         #   particular customer 'fell' within the specified range(s). Print out the
         #   results.
  for (i in final)
    printf("%s -> [%d]\n", i, final[i])
}