awk '
function AddFieldData(field)    {if ( (field, $field) in data) return                           # if field No. and field contents occurred (and registered) before, quit function
                                                                                                # data is an array whose elements'' contents don''t count, only its indices

                                 data[ field, FieldValue [field, ++count[field] ] = $field]     # this is quite complex (array elements are defined on first reference):
                                                                                                # register field No. and field contents as index into data array, and
                                                                                                #   at the same time, create FieldValue array element holding field contents and indexed
                                                                                                #   by field No. and an incremented counter for the field No. 
                                 if (count[field] > maxr) maxr = count[field]                   # keep max count across ALL fields (i.e. the No. of lines to be printed
                                                                                                #   e.g. for three unique values in field2 we need to print three lines)
                                 if (field > maxc) maxc = field                                 # keep max of NF across all lines
                                }

        {for(i = 1; i <= NF; i++) AddFieldData(i)                                               # main: call above function for ALL fields in ALL lines filling the necessary arrays
        }

END     {for (i = 1; i <= maxr; i++)                                                            # print maxr lines with
           for (j = 1; j <= maxc; j++)                                                          # maxc fields, each
                printf("%s%s", FieldValue[j, i], (j == maxc) ? ORS : OFS)                       # a sort of random distribution of unique field values ; after last (maxc)
                                                                                                # field print line feed (ORS) else field separator (OFS, space)
        }
'  file