#!/usr/xpg4/bin/sh
/usr/xpg4/bin/awk '
# repDigits(1, split1, n1, m) or
# repDigits(2, split2, n2, m) reconstituutes the field specified by the 1st
# argument with data from the array specifeid by the 2nd argument containing
# the # of elements specified by the 3rd argument.  The digits in the 1st 4
# elements of splitN will be replaced by the same number of alphabetic
# characters:  if both fields are being replaced, digits are replaced with "f";
# if only field 1 is being replaced, digits are replaced with "g"; and if only
# field 2 is being replaced, digits are replaced with "h".
function repDigits(field, fieldData, fieldCount, repIndex,      i) {
        $field = sprintf("%.*s.%.*s.%.*s.%.*s",
                        length(fieldData[1]), rep[repIndex],
                        length(fieldData[2]), rep[repIndex],
                        length(fieldData[3]), rep[repIndex],
                        length(fieldData[4]), rep[repIndex])
        for(i = 5; i <= fieldCount; i++)
                $field = $field "." fieldData[i]
}
BEGIN { # Initialize replaceemnt strings for digits in IP addresses
        rep[1] = "gggggggggg"   # 1st field only
        rep[2] = "hhhhhhhhhh"   # 2nd field only
        rep[3] = "ffffffffff"   # both fields
}
NF == 7 {
        # Split the first two fields on this line into the arrays split1[] and
        # split2[] using a period as the field separator and then verify that
        # each array has at least four elements and that the 1st four elements
        # of each is numeric.  The variable m is then set as follows:
        #    0=>neither field meets the criteria
        #    1=>the 1st field meets the criteria, but the 2nd argument does not
        #    2=>the 2nd field meets the criteria, but the 1st argument does not
        #    3=>both arguments meet the criteria
        m = 0
        n1 = split($1, split1, /[.]/)
        if(n1 >= 4 &&   split1[1] ~ /^[0-9]+$/ &&
                        split1[2] ~ /^[0-9]+$/ &&
                        split1[3] ~ /^[0-9]+$/ &&
                        split1[4] ~ /^[0-9]+$/) m = 1
        n2 = split($2, split2, /[.]/)
        if(n2 >= 4 &&   split2[1] ~ /^[0-9]+$/ &&
                        split2[2] ~ /^[0-9]+$/ &&
                        split2[3] ~ /^[0-9]+$/ &&
                        split2[4] ~ /^[0-9]+$/) m += 2
        if(m % 2) repDigits(1, split1, n1, m)
        if(m >= 2) repDigits(2, split2, n2, m)
}
1       # print the (possibly updated) line' input