UNIX for Dummies Questions & Answers

#!/usr/bin/sed -f
# Another way to do it - adapted from a script found here
# http://sed.sourceforge.net/grabbag/s.../remccoms1.sed
# to allow c++ // style comments to be removed
#
# Cheers, ZB
# Comments added by ZB

# If pattern is not matched (i.e. line does not contain /*
# then branch to label :c
/\/\*/!bc

# Okay - line must contain /*, or we've branched here
# if line doesn't contain */ then append contents of next line to
# pattern space and continue - we must have got here by a branch
# to :a (or start of comment), so we can assume we're
# processing a comment
:a
/\*\//!{
N
# branch back to :a to continue processing comment
ba
}
:c
# okay - not multiline comment - could be code, or single line
# comment (including embedded newlines)

# replace single line comment with nothing (which could be 
# formed from lines of a multiline comment with newlines
# embedded from the "N" command above )
s:/\*.*\*/::

# replace // comment with nothing
s://.*$::g