Shell Programming and Scripting

#!/bin/awk -f
#           Awk program file.
# Name    : histo.awk
# Purpose : 
# Syntax  : ...| awk -f histo.awk 
#-------------------------------------------------------------------------------
# On range dans nbclasse 
# < min : va dans histogramme[0]
# >= max : va dans histogramme[nbclasse+1]
#
# Getting parameters from header
#
/^H/ {
  
  min = $2
  max = $3
  intervalle = $4

  nbclasse = (max-min)/intervalle

} 

#
# Distributing results
#
$0 !~/^H/ {

   if ( isnotfirst == 0 ) {
      min_ech = $1
      max_ech = $1
   } else {
      if ( min_ech > $1 )
         min_ech = $1
      if (max_ech < $1 )
         max_ech = $1
   }
   isnotfirst = 1 

   value = $1 
   classe = int((value-min)/(max-min)*nbclasse) + 1

   if ( value < min  ) 
      classe  = 0
   if ( value >= max )
      classe = nbclasse+1

   histogramme[classe]++
   mytot++
   if ( value > min && value <= max ) {
      TOTAL += value
      nb_average ++
   } 
      
} 


#
# Drawing graph
#
END {

   # Get number of samples in the most filled class
   for ( i =0 ; i<=nbclasse +1 ; i ++ )
      if (histomax <histogramme[i] )
         histomax = histogramme[i]
  
   printf ( "Class          %%     Nb Bargraph\n" )

   # Print lower than limit occurrences
   printf ( " <= %d      : %2.0f %6d ", min, histogramme[0]/ mytot * 100, 
      histogramme[0] ) 
   bar(histogramme[0], histomax) 

   # To check...
   histot+= histogramme[0]
 
   # Print the distribution
   for ( i = 1; i <= nbclasse;i ++ ) {

      percent = histogramme[i] / mytot * 100;
      sumpercent += percent

      printf ( "[%3d - %3d[ : %2.0f %6d ", min + (i-1) * intervalle, 
         min + i * intervalle, percent,  histogramme[i] )
      bar(histogramme[i],histomax)

      # To check...
      histot+= histogramme[i]

   }

   # Print higher than limit occurrences
   printf ( " >  %d      : %2.0f %6d ", max, 
      histogramme[nbclasse+1]/ mytot * 100, histogramme[nbclasse+1] ) 
   bar(histogramme[nbclasse+1],histomax )

   # To check...
   histot+= histogramme[nbclasse+1]

   printf( "My total           : %d\n", mytot )  
   printf( "Sum of all classes : %d\n", histot )  
   printf( "Sum of percentages : %.3f\n", 
      sumpercent + (histogramme[0]+histogramme[nbclasse+1])/ mytot * 100 )
   printf( "Average (in limits): %.3f\n", TOTAL/nb_average )
   printf( "Minimum            : %.3f\n", min_ech )  
   printf( "Maximum            : %.3f\n", max_ech )  
 

}

function bar ( nb, max ) {

   for ( j = 0.0 ; j < nb; j+= max/50 )
      printf ( "-" )
   printf ( "\n" )

}

awk 'BEGIN {
           printf ("H 30 75 2\n")
           }
           {
            printf ("%10.2f\n", $7)
           }' patt_length.txt | histo.awk