Shell Programming and Scripting

cat beca123456.input
!@#$%2QW5QWERTAB$%^&*
!@#$%4AvDf2QWER
3BHuI4RtYU2vGP
$%$6ABcdEf)-2yg*%/LK@~~()

awk '
{
    for(i=1;i<=length($0);i++){
        ch = substr($0, i, 1)
        if(ch ~ /[0-9]/){
            pat = substr($0, i+1, ch)
            multi[pat]++;
            i += ch
        }
        else if(ch ~ /[a-zA-Z]/){
            single[ch]++
        }
        
    }
}

{
    printf "%s", $0
    for (s in single){
       printf "|%d:%s", single[s], s 
       delete single[s]
    }

    for (s in multi){
      m == "" ? m="|"multi[s]":"s : m=m"; "multi[s]":"s
      delete multi[s]
    }
    print m
    m = ""

}' beca123456.input

!@#$%2QW5QWERTAB$%^&*|1:A|1:B|1:QWERT; 1:QW
!@#$%4AvDf2QWER|1:R|1:E|1:AvDf; 1:QW
3BHuI4RtYU2vGP|1:P|1:I|1:RtYU; 1:vG; 1:BHu
$%$6ABcdEf)-2yg*%/LK@~~()|1:K|1:L|1:yg; 1:ABcdEf

awk '
BEGIN {	printf("String   #_of_occurrences_of__pattern:pattern...\n")
}
{	printf("%s", left = $0)
	while(match(left, /[[:alnum:]]+/)) {
		# Throw away leading non-digit, non-alpha characters.
		if(RSTART > 1)
			left = substr(left, RSTART)
		if((num = left + 0) > 0) {
			# We have a string starting with a leading digit string.
			p = substr(left, len = length(num) + 1, num)
			left = substr(left, len + num)
			if(p in mcnt) {
				# We have seen this pattern before.
				mcnt[p]++
			} else {# We have not seen this pattern before.
				mcnt[mplist[++nmp] = p] = 1
			}
		} else {
			# We have a single alphabetic character string.
			p = substr(left, 1, 1)
			left = substr(left, 2)
			if(p in scnt) {
				# We have seen this pattern before.
				scnt[p]++
			} else {# We have not seen this pattern before.
				scnt[splist[++nsp] = p] = 1
			}
		}
	}
	# Print the results for this input line.
	# Print single character patterns.
	for(i = 1; i <= nsp; i++) {
		printf("   %d:%s", scnt[splist[i]], splist[i])
		delete scnt[splist[i]]
		delete splist[i]
	}
	# Print multiple character patterns.
	for(i = 1; i <= nmp; i++) {
		printf("   %d:%s", mcnt[mplist[i]], mplist[i])
		delete mcnt[mplist[i]]
		delete mplist[i]
	}
	print ""
	nmp = nsp = 0
}' file

!@#$%2QW5QWERTAB$%^&*
!|@|#|$|%|2QW|5QWERT|A|B|$|%|^|&|*
!@#$%2QW5QWERTAB$%^&*2QW5QWERTABAB
12ABCDEFGHIJKLMNABC
12ABCDEFGHIJKLMNABC#12ABCDEFGHIJKLMNDEF
~!@#$%^&*()_+
Aa@52ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz#aA
AAAAAAAAAAAAAAAAAAAAAAAaaaaaabbbbbbAAAAAAAAAAAAAAAAAA
!@#$%3ABC$%DE$%4Fghi3ABC^&*D$%^&

String   #_of_occurrences_of__pattern:pattern...
!@#$%2QW5QWERTAB$%^&*   1:A   1:B   1:QW   1:QWERT
!|@|#|$|%|2QW|5QWERT|A|B|$|%|^|&|*   1:A   1:B   1:QW   1:QWERT
!@#$%2QW5QWERTAB$%^&*2QW5QWERTABAB   3:A   3:B   2:QW   2:QWERT
12ABCDEFGHIJKLMNABC   1:M   1:N   1:A   1:B   1:C   1:ABCDEFGHIJKL
12ABCDEFGHIJKLMNABC#12ABCDEFGHIJKLMNDEF   2:M   2:N   1:A   1:B   1:C   1:D   1:E   1:F   2:ABCDEFGHIJKL
~!@#$%^&*()_+
Aa@52ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz#aA   2:A   2:a   1:ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz
AAAAAAAAAAAAAAAAAAAAAAAaaaaaabbbbbbAAAAAAAAAAAAAAAAAA   41:A   6:a   6:b
!@#$%3ABC$%DE$%4Fghi3ABC^&*D$%^&   2:D   1:E   2:ABC   1:Fghi

awk '
        {printf "%s", $0
         gsub (/[^A-Za-z0-9]/, "")
         n = split ($0, DIG, "[A-Za-z]*")
         m = split ($0, CHR, "[0-9]*")
         S = CHR[1]
         B = 1 + !(DIG[1])
         for (i=B; i<n; i++)    {IX = i - B + 2
                                 TMP = substr (CHR[IX], 1, DIG[i])
                                 PAT[TMP]++
                                 sub ("^" TMP, _, CHR[IX])
                                 S = S CHR[IX]
                                }
         for (i=split (S, T, ""); i>0; i--) SGL[T[i]]++
         for (p in PAT) printf "\t%d:%s", PAT[p], p
         for (s in SGL) printf "\t%d:%s", SGL[s], s
         printf "\n"
         S = ""
         delete PAT
         delete SGL
        }
' file

B = 1 + !(DIG[1])

!@#$%12QWtttttttttt5QWERTAB$%^&*

!@#$%12QWtttttttttt5QWERTAB$%^&*   1:A   1:B   10:t   1:Q   1:W   1:2; 1:QWERT

!@#$%12QWtttttttttt5QWERTAB$%^&*   1:A   1:B   1:QWtttttttttt   1:QWERT

awk '
{
    for(i=1;i<=length($0);i++){
        ch = substr($0, i, 1)
        if(ch ~ /[0-9]/){
            d = ""
            while(ch ~ /[0-9]/){
               d = d ch
               ch = substr($0, ++i, 1)
            }
            pat = substr($0, i, d)
            multi[pat]++
            i += (d-1)
       }
        else if(ch ~ /[a-zA-Z]/){
            single[ch]++
        }
    }
}
{
    printf "%s", $0
    for (s in single){
       printf " %d:%s", single[s], s
       delete single[s]
    }

    for (s in multi){
      m == "" ? m=" "multi[s]":"s : m=m"; "multi[s]":"s
      delete multi[s]
    }
    print m
    m = ""
}' beca123456.file