Shell Programming and Scripting

2015-08-25 08:41:23,507 INFO Successful run: some procedure @ poolname (setup: 19ms / exec: 21ms) (requestor: requestorip) (ProcessID: processID)

ProcessID: 108786b:14f62721fb3:-7fa2
ProcessID: 108786b:14f62721fb3:-7fa1
ProcessID: 108786b:14f62721fb3:-7fa0
ProcessID: 108786b:14f62721fb3:-7f9f
ProcessID: 108786b:14f62721fb3:-7f9e
ProcessID: 108786b:14f62721fb3:-7f9d

awk -F'[()]' '!/ProcessID: /{next} {p=$(NF-1)} NR==FNR{A[p]++; next} p in A{print p}'  file1.log file2.log

awk -F'[()]' '!/ProcessID: /{next} {p=$(NF-1)} NR==FNR{A[p]++; next} !(p in A){print p}'  file1.log file2.log

awk -F'[()]' '		# Set input field separators to the open and close
			# parenthesis characters.
!/ProcessID: /{next}	# Skip any line that does not contain "ProcessID: "
{p=$(NF-1)}		# Set p to the last string on the line between "(" and
			#    ")".  Presumably this sets p to the processID on
			#    the current input line from either input file.
NR==FNR{A[p]++; next}	# If this line was read from the 1st input file,
			#    increment the count of the number of time we have
			#    seen this processID in the 1st input file, and
			#    skip to the next input line.
p in A{print p}		# If the processID seen on this line in the 2nd input
			#    file was also seen in the 1st input file, print
			#    the processID.
' file1.log file2.log	# End the awk script & name the 1st and 2nd input files.

!(p in A){print p}	# If the processID seen on this line in the 2nd input
			#    file was not seen in the 1st input file, print
			#    the processID.

NR==FNR{A[p]++; next}

NR==FNR{A[p]; next}