Shell Programming and Scripting

Hi All I am just trying to compare 2 file using column information using following code

Code:

awk '
NR==FNR {A[$1,$2,$3,$4,$5,$6,$7,$8]=$9; next}
{B=A[$1,$2,$3,$4,$5,$6,$7,$8]; print $0,B""?B:" Not -In file" }
' OFS="\t" file1 file2

if file1 matches with file2 then print

Code:

$9

content in file 1 along with file2

Code:

 $0

suppose if I keyed on only

Code:

$1

in array then I could able to see result but I want to compare at least 5 column out of 8

Those who know please help

As usual, you did not give a clear specification of the output you want. If this isn't what you want, maybe it will be close enough for you to figure out how to fix it to meet your unstated requirements:

Code:

awk '
FNR == NR {
        c = NR  # # of lines in 1st file
        for(i = 1; i <= 9; i++)
                a[c, i] = $i
        next
}
{       p = 0   # # of lines matched
        for(i = 1; i <= c; i++) {
                m = 5   # # of fields that must match
                for(j = 1; j <= 8 && m; j++)
                        if(a[i, j] == $j) m--
                if(m) continue
                # We matched enough fields; print this as a matched line.
                print $0, a[i, 9]
                p++
        }
        # If we did not find any matching lines, print the not found message
        if(p == 0) print $0, "Not -In file"
}' OFS="\t" file1 file2

As always, if you're using a Solaris/SunOS system, use /usr/xpg4/bin/awk or nawk instead of awk.

Sir my problem is very simple sir, I have 2 files 1 file is having records say for instance 10 columns and 25 rows, and in another file 10 columns and 15 rows with some update information in 9th column, usually I is to compare using code tagged in #1 post, but I didn't understand why my code is not working ...whether Sir FS of 2 files need to be same ? or any other specific reason

What is not working with your code? While your problem may be very simple, your specification is not. Wildest guessing does not lead to an acceptable proposal. Please post input samples, desired output, and an explanation on how to get from A to B.

I have color coded the various requirements in the following description of how I interpreted what you requested. Following that is another copy of my script again with corresponding sections of the code highlighted using the same colors.

In your 1st example you had at least 9 fields in file1 (with no specified number of rows) and at least 8 fields in file2 (with no specified number of rows) and with the separator between fields unspecified. I interpreted your sample code and your statements to mean that if at least 5 fields out of the first 8 fields in a line in file2 match the corresponding fields in any line in file1, that line from file2 is to be printed followed by a tab followed by the contents of field 9 of the matched line from file1. Every line in file1 is supposed to be checked to see if there is a match for each line read from file2. If there are no matches in file1 for a line in file2, that line from file2 is to be printed followed by a tab followed by the text " Not -In file". (My awk script removed the first space in this string since I didn't see any need for a space following the tab separating this text from the original contents of the line from file2. You can easily put the space back, change the text in this message, or delete it entirely, if you want to.)

Code:

awk '
FNR == NR {
        c = NR  # # of lines in 1st file
        for(i = 1; i <= 9; i++)
                a[c, i] = $i
        next
}
{       p = 0   # # of lines matched
        for(i = 1; i <= c; i++) {
                m = 5   # # of fields that must match
                for(j = 1; j <= 8 && m; j++)
                        if(a[i, j] == $j) m--
                if(m) continue
                # We matched enough fields; print this as a matched line.
                print $0, a[i, 9]
                p++
        }
        # If we did not find any matching lines, print the not found message
        if(p == 0) print $0, "Not -In file"
}' OFS="\t" file1 file2

With all of the awk scripts I have provided for you in this forum in the past, and the descriptions I have provided on how they work, I am confident that you can easily modify this script to meet your changed requirements and produce the output you want. In this case you have gone from adding a field 9 from file1 to the end of matched lines in file2 to replacing field 9 in matched lines, matching at least 5 of the first 8 fields in each line to matching an unspecified number of fields in the first 10 fields, and specifying what is to happen when there is no match to saying nothing about that case. In this case you specify the number of lines in both files, but the script I provided doesn't care how many lines are in either file, although it could run out of memory if there is a HUGE amount of data in the 9 fields that have to be saved from each line in file1.

For the record, what you original code did was the following: If the first 8 fields in a line in file1 match every one of the corresponding first 8 fields (ignoring the field separators between those fields) print the line from file2 followed by a tab followed by field 9 from a matched line in file1. If no match is found, print the line from file2 followed by a tab followed by " Not -In file". That script made absolutely no attempt to accept a match of 5 out of 8 fields; it was only looking for a an 8 out of 8 match.

IF YOU WANT ANY HELP FROM ME IN THE FUTURE, YOU NEED TO EXPLICITLY STATE YOUR REQUIREMENTS AND PROVIDE SAMPLES IN YOUR FIRST MESSAGE RATHER THAN MAKING US GUESS AT WHAT YOU WANT DONE AND CHANGING THE REQUIREMENTS WITH EACH FOLLOW ON POST. Pardon me for yelling; but you must understand by now how frustrating it is to see this pattern of behavior repeated in every one of your threads.

Dear Don Cragun and RudyC,

This is to convey to you my sincere apologies for any inconvenience you may have experienced in past and present thread.

You can expect better and more appropriate behavior from me in the future. I have learned from this experience and understand that a certain level of refrain and professionalism is expected of me in the forum.

I recognize your dedication toward forum and your commitment. I hope our relationship is undamaged from my actions and that I can continue to learn and grow under your guidance.

Again, please accept my most genuine apologies and if there is anything you would like to discuss about this event, please feel free to discuss it with me.

Akshay Hegde

Apologies accepted but not needed. Pls see and answer post #4.