Shell Programming and Scripting

awk '{ A[$2" "$3]+=$4 } END { for(X in A) print X, A[X] }' filename

          hTRBJ2-5 hTRBJ1-2 hTRBJ2-3 hTRBJ2-1 hTRBJ1-5 hTRBJ1-4 hTRBJ1-1
--------- -------- -------- -------- -------- -------- -------- --------
hTRBV12-4        2        0        0        0        0        0        0
  hTRBV18        0        2        0        0        2        2        2
 hTRBV5-1        0        4        0        0        0        0        0
  hTRBV27        0        0        2        0        0        0        0
 hTRBV6-4        0        0        0        2        0        0        0
hTRBV11-1        0        0        0        2        0        0        0

#!/bin/ksh
awk -F, '{
        A[$2" "$3] += $4
        if(! ($2 in row)) {
                # We haev a new $2 value which will be printed as a new row.
                # Save ordering info for this row and max width of column 1.
                row[$2] = ++rc
                rh[rc] = $2
                if(cw[0] < length($2)) cw[0] = length($2)
        }
        if(! ($3 in col)) {
                # We have a new $3 value which will be printed as a new column.
                # Save ordering info and width for this column
                col[$3] = ++cc
                ch[cc] = $3
                cw[cc] = length($3)
        }
}
END {   # Print header rows
        for(i = 0; i <= cc; i++)
                printf("%*.*s%s", cw[i], cw[i], ch[i], i < cc ? " " : "\n")
        for(i = 0; i <= cc; i++)
                printf("%*.*s%s",
                        cw[i], cw[i], "------------------", i < cc ? " " : "\n")
        # Print data rows
        for(i = 1; i <= rc; i++) {
                # Print 1st two columns.
                printf("%*s%*d", cw[0], rh[i], cw[1] + 1, A[rh[i] " " ch[1]])
                # Print remaining columns.
                for(j = 2; j <= cc; j++)
                        printf("%*d", cw[j] + 1, A[rh[i] " " ch[j]])
                printf("\n")
        }
}' filename