Shell Programming and Scripting

Code:

awk '
(FILENAME!="mainfile.txt") { a[$4]=FILENAME ; next}
( $3 in a ) {print $0,"\t",a[$3] }
' server3.txt server2.txt server1.txt mainfile.txt

Looks shorter.

The programme reads each input file, in order, that is listed on the command line following the programme; server3.txt, server2.txt, server1.txt, and mainfile.txt. The variable FILENAME is set by awk to the name of the file that is currently being processed.

For each record, when the filename is server?.txt, it saves the current filename into the associative array 'a' using the IP address (the contents of the fourth field or $4) as the index. The 'next' statement causes awk to stop processing the current record, read the next record and start processing that record from the top of the programme.

Code:

(FILENAME=="server3.txt") { a[$4]=FILENAME ; next}
(FILENAME=="server2.txt") { a[$4]=FILENAME ; next}
(FILENAME=="server1.txt") { a[$4]=FILENAME ; next}

When the input record does not come from server?.txt, none of the statements with 'next' are matched and the last line of the programme is executed. The third field, the IP address, is used as an index into the array 'a' and if the array contains a non-null value, it prints the input record from the main file and the contents of a[$3] which is the name of the last server?.txt file that the address was seen in.

Code:

( $3 in a ) {print $0,"\t",a[$3] }

It could have also been written to be more clear to a beginner:

Code:

{ 
   if( a[$3] != "" )
      print $0 " \t" a[$3];
}

Yes, it looks shorter, but more importantly it allows a variable number of server*.txt files to be processed without requiring the code to change.

It might also be nice to write the line

Code:

(FILENAME!="mainfile.txt") { a[$4]=FILENAME ; next}

as

Code:

(FILENAME!="mainfile.txt") { a[$4] = a[$4] FILENAME " "; next}

which allows for the ip address to exist in multiple server*.txt files and to have each of those names presented rather than the name of the last file that the address was noticed in.