router::simple::cookbook(3pm) [debian man page]

Router::Simple::Cookbook(3pm)				User Contributed Perl Documentation			     Router::Simple::Cookbook(3pm)

NAME

       Router::Simple::Cookbook - The Router::Simple Cookbook

FAQ

   How to create Sinatra-ish framework with Router::Simple?
       Please read the following example code.

	   package MySinatraish;
	   use Router::Simple;
	   use Plack::Request;

	   sub import {
	       my $pkg = caller(0);
	       my $router = Router::Simple->new();
	       my $any = sub ($$;$) {
		   my ($pattern, $dest, $opt) = do {
		       if (@_ == 3) {
			   my ($methods, $pattern, $code) = @_;
			   ($pattern, {code => $code}, +{method => [ map { uc $_ } @$methods ]});
		       } else {
			   my ($pattern, $code) = @_;
			   ($pattern, {code => $code}, +{});
		       }
		   };
		   $router->connect(
		       $pattern,
		       $dest,
		       $opt,
		   );
	       };
	       no strict 'refs';
	       # any [qw/get post delete/] => '/bye' => sub { ... };
	       # any '/bye' => sub { ... };
	       *{"${pkg}::any"} = $any;
	       *{"${pkg}::get"} = sub {
		   $any->([qw/GET HEAD/], $_[0], $_[1]);
	       };
	       *{"${pkg}::post"} = sub {
		   $any->([qw/POST/], $_[0], $_[1]);
	       };
	       *{"${pkg}::as_psgi_app"} = sub {
		   return sub {
		       if (my $p = $router->match($_[0])) {
			   [200, [], [$p->{code}->()]];
		       } else {
			   [404, [], ['not found']];
		       }
		   }
	       };
	   }

	   package MyApp;
	   use MySinatraish;
	   get '/' => sub {
	       'top';
	   };
	   post '/new' => sub {
	       'posted';
	   };
	   as_psgi_app;

   How to switch from HTTPx::Dispatcher?
       HTTPx::Dispatcher is class specific declararative router.

	   package MyApp::Dispatcher;
	   use HTTPx::Dspatcher;
	   connect '/', {controller => 'foo', action => 'bar'};
	   1;

       The following script is same as above.

	   package MyApp::Dispatcher;
	   use Router::Simple::Declare;

	   my $router = router {
	       connect '/', {controller => 'foo', action => 'bar'};
	   };
	   sub match { $router->match() }

   How to use Router::Simple with non-strictly-MVC application?
	   use Router::Simple::Declare;
	   my $router = router {
	       connect '/foo/bar/' => { 'target' => '/foobar.asp' };
	       connect '/topics/:topic' => { target => '/my-topic.asp' };
	       connect '/products/{Category:.*}' => { target => '/products.asp', Category => 'All' };
	       connect '/zipcode/{zip:[0-9]{5,5}}' => {target => '/zipcode.asp' };
	   };

       You can pass the target path as destination.

AUTHOR

       Tokuhiro Matsuno <tokuhirom AAJKLFJEF GMAIL COM>

LICENSE

       Copyright (C) Tokuhiro Matsuno

       This library is free software; you can redistribute it and/or modify it under the same terms as Perl itself.

SEE ALSO

       Router::Simple

perl v5.14.2							    2011-05-15					     Router::Simple::Cookbook(3pm)

Check Out this Related Man Page

Web::Simple::Deployment(3pm)				User Contributed Perl Documentation			      Web::Simple::Deployment(3pm)

NAME

       Web::Simple::Deployment - various deployment options

DESCRIPTION

       This file documents common deployment methods for Web::Simple. If you feel one is missing, please ask in the IRC channel and we'll work
       with you to add it.

CGI

       The most basic deployment option is as a CGI script loading and running your Web::Simple-module:

	 #!/usr/bin/env perl

	 use Your::Web::Simple::App;
	 Your::Web::Simple::App->run_if_script;

       Save that as script.cgi and your web server will handle it correctly.

Plack-Server
       This works in with exactly the same code as CGI deployment. However instead of letting your web server load script.cgi, you run this on the
       command line:

	 plackup script.cgi

   Self-contained CGI
       Sometimes your app is so small that you have only one or two tiny classes that you want to run as a CGI script. Web::Simple offers a
       helpful mechanism to achieve that.

	 #!/usr/bin/env perl

	 use Web::Simple 'HelloWorld';	 # enables strictures and warnings for the file
					 # additionally, HelloWorld is upgraded to a
					 # Web::Simple application
	 {
	   package HelloWorld;

	   sub dispatch_request {
	     sub (GET) {
	       [
		 200,
		 [ 'Content-type', 'text/plain' ],
		 [ 'Hello world! It is a fine ' . HelloWorld::Helper->day ]
	       ]
	     },
	     sub () {
	       [ 405, [ 'Content-type', 'text/plain' ], [ 'Method not allowed' ] ]
	     }
	   }
	 }

	 {
	   package HelloWorld::Helper;

	   use DateTime;

	   sub day {
	     return DateTime->now->day_name;
	   }
	 }

	 HelloWorld->run_if_script;

AUTHORS

       See Web::Simple for authors.

COPYRIGHT AND LICENSE

       See Web::Simple for the copyright and license.

perl v5.14.2							    2012-05-07					      Web::Simple::Deployment(3pm)

Linux and UNIX Man Pages

router::simple::cookbook(3pm) [debian man page]

Check Out this Related Man Page