Your requirements are not at all clear:If what you are trying to do is to replace every occurrence of the string BOO in your input file with the contents of the shell variable ABC, you might want to try something more like:

Code:

ABC=CHICKEN
awk -v ABC="$ABC" '
BEGIN {	FS = OFS = "|"
}
{	gsub(/BOO/, ABC)
}
1' "$1"

If what you are trying to do is to replace the contents of every field whose value is entirely the case insensitive string BOO with the contents of the shell variable ABC, you might want to try something more like:

Code:

ABC=CHICKEN
awk -v ABC="$ABC" '
BEGIN {	FS = OFS = "|"
}
{	for(i = 1; i <= NF; i++)
		if($i ~ /^[Bb][Oo][Oo]$/)
			$i = ABC
}
1' "$1"

If what you are trying to do is to replace the contents of field $4 with the contents of the shell variable ABC if and only if that field contains the string BOO, you might want to try something more like:

Code:

ABC=CHICKEN
awk -v ABC="$ABC" '
BEGIN {	FS = OFS = "|"
}
$4 == "BOO" {
	$4 = ABC
}
1' "$1"

Of course, all of the above assume that you are using a shell that is based on Bourne shell syntax (not a shell that is based on csh syntax) and that you are not using a Solaris/SunOS system (in which case you would need to use /usr/xpg4/bin/awk or nawk instead of awk).

If none of the above are what you are trying to do and what rdrtx1 guessed is not what you are trying to do then please give a much more detailed, clear description of what your code is supposed to do along with a clear specification of what shell and operating system you're using so we might have a better chance of determining what needs to be done to achieve your desired outcome.