First, sed does not have the ability to perform arithmetic operations on strings. Second, your first sed command does not contain a valid substitute command. Third, your second sed command tries to edit a directory (i.e., ./) and sed only operates on text files; not directories. And, fourth, the regular expression that is your search pattern in your second sed command looks for a single digit followed by a plus-sign followed by a period followed by a single digit followed by a plus-sign followed by a period followed by a single digit followed by a plus-sign followed by a period followed by a single digit, but that pattern does not match any text in any line in your sample input.

The awk utility, however, is perfectly capable of simple arithmetic like this. However, you will not get unique integer values if any of the four numbers in an IP address is larger than 255 with the algorithm you're using to convert an IP address to an integer AND, I don't get the output values you say you expect for any of the in IP addresses you supplied??? If all four numbers in your IP addresses are in the range 0 through 255, using the algorithm you specified, the result will fit in an unsigned 32-bit integer. It will fit in a signed 32-bit integer if and only if the 1st number is in the range 0 through 127.

You might try the following awk script and see if it comes close to the results you want:

Code:

awk '
function IP2int(IP,	a, n) {
	n = split(IP, a, /[.]/)
	if(n != 4 || a[1] > 255 || a[2] > 255 || a[3] > 255 || a[4] > 255)
		return("invalid IP")
	return(a[1] * 256 ^ 3 + a[2] * 256 ^ 2 + a[3] * 256 + a[4])
}
BEGIN {	FS = OFS = "\t"
}
{	print $0, IP2int($3), IP2int($4)
}' input

with the sample input you showed us in post #1, the above code produces the output:

Code:

12	3	5.122.281.413	172.31.15.220	3421	4133	2	2	1454	3421	4133	2	2	0		invalid IP	2887716828
12	44036	214.215.52.146	90.123.245.211	2312	3911	4	4	521	2312	3911	4	4	1		3604427922	1518073299
14	504	6.254.324.219	192.61.27.120	4444	5611	7	5	1415	4444	5611	7	5	1		invalid IP	3225230200
13	9	146.216.51.151	5.132.212.115	5432	6123	9	1	78	5432	6123	9	1	1		2463642519	92591219
16	41228	96.201.221.214	5.132.212.115	3411	5120	3	3	1358	3411	5120	3	3	1	1623842262	92591219

Note that there is an empty field before the two added fields in all but the last line of input because your sample input file has an empty field (i.e., a tab character) at the end of each of those lines.

You didn't tell us what shell or operating system you're using. If you want to try this on a Solaris/SunOS system, change awk in the above script to /usr/xpg4/bin/awk or nawk.