#!/bin/ksh
awk '
BEGIN {	# Before reading 1st line from the input file, set output field
	# separator to <tab> and print heading.
	OFS = "\t"
	print "Point1", "Point2", "Number_of_Studies_with_Different_Values"
}
NR == 1 {
	# Skip over the input file header line.
	next
}
$1 != last {
	# If the 1st field has changed, process all of the lines read for the
	# previous value of the 1st field.
	count()

	# Save the current value of the 1st field.
	last = $1
}
{	# Increment the number of lines seen for this 1st field value and save
	# the point name and the value from the current line.
	p[++n] = $2
	v[n] = $3
}
END {	# Process the last 1st field value.
	count()

	# Print the accumulated results.
	for(i in diffs)
		# Uncomment one and only one of the following lines.
		print i, diffs[i] | "sort"	# use this to sort output
		# print i, diffs[i]		# use this for unsorted output
}
function count(		i, j) {
	# Process the set of lines for a given 1st field value.
	# There are "n" lines in the set.  for each of the 1st "n-1" lines
	# in this set...
	for(i = 1; i < n; i++)
		# for each of the remaining lines in the set...
		for(j = i + 1; j <= n; j++)
			# if the values for those two points are different...
			if(v[i] != v[j])
				# Increment the number of times this pair of
				# points (with the two points sorted by point
				# names) has had different values.
				diffs[(p[i] < p[j]) ?  p[i] OFS p[j] : \
				    p[j] OFS p[i]]++

	# Reset the line counter for the next set.
	n = 0
}' dataset

Point1	Point2	Number_of_Studies_with_Different_Values
p1	p2	1
p1	p4	1
p1	p5	2
p2	p3	1
p2	p4	2
p2	p5	1
p3	p4	1
p3	p5	2

Point1	Point2	Number_of_Studies_with_Different_Values
p3	p4	1
p3	p5	2
p2	p3	1
p2	p4	2
p2	p5	1
p1	p2	1
p1	p4	1
p1	p5	2