Instead of searching the web for explicit ways to perform very particular formatting requests, try reading the awk man page on your system and see if you can figure out how to modify the scripts you have been given to meet each of your new requirements. We are happy to help you learn how to use awk if there is something you can't figure out; but we are here to act as your unpaid programming staff for countless minor changes...

I will give you these two new additional trivial changes this time. Next time, we will expect you to show us what changes you want to your output and show us how you have tried to modify this awk script to meet your new requirements.

Code:

#!/bin/ksh
for file in [A-Z][A-Z][A-Z][0-9][0-9][0-9][0-9]0[01][0-9]
do	m=${file#????????}
	y=${file#???}
	y=${y%???}
	jd1=$(printf '%(%j)T' "$m/01/$y")
	printf '%s,%s\n' "$file" "$jd1"
done | awk -F ' *, *' '
FNR == NR {
	jdb[ARGV[ARGC++] = $1] = $2 - 1
	next
}
NF == 0 {
	next
}
FNR == 1 {
	nofny = substr(FILENAME, 1, 7) ".txt"
	if(ofny && ofny != nofny)
		close(ofny)
	ofny = nofny
	if(ofnm)
		close(ofnm)
	ofnm = FILENAME ".txt"
	gsub(/,/, " ")
	print > ofnm
	print > ofny
	next
}
FNR == 2 {
	gsub(/,/, " ")
	print > ofnm
	print > ofny
	next
}
FNR == 3 {
	printf("Julian  %s  %s\n", $2, $9) > ofnm
	printf("Julian  %s  %s\n", $2, $9) > ofny
	fmt = sprintf("   %%03d  %%4.4s  %%%d.1f\n", length($9))
	next
}
{	printf(fmt, $1 + jdb[FILENAME], $2, $9 ? $9 : -9) > ofnm
	printf(fmt, $1 + jdb[FILENAME], $2, $9 ? $9 : -9) > ofny
}' -

Note that the format string for printing field 9 has changed from %x.xs where x is the width of the header for field 9 (which displayed the contents of field 9 as a right justified string) to %x.1f (which displays the contents of field 9 as an x character floating point value with 1 digit displayed after the decimal point). And, changing $9 ? $9 : "-" in the printf statement printing field 9 (which printed the contents of field 9 if the contents is not the empty string and is not zero, or printed the string "-" if the contents of field 9 is zero or is an empty string) to ($9 != "") ? $9 : -9 causes the contents of field 9 to be printed if it is not an empty string, or to print -9 if the contents of field 9 is an empty string.