Assuming that every segment in your file contains a cn=name line, this might be a little bit simpler (and more portable) to get the output you said you wanted:

Code:

awk 'NF==1' RS= file

Modifying your code so it prints the names of users (if cn=name identifies a user's name) that do not have an authtime=year entry (although naming the variable that contains that list lastauthtime is not at all descriptive), you could try:

Code:

awk '
BEGIN {
        FS="\n"
        RS=""
}

NF==1 {
        sub(/cn=/,"",$1)
        lastauthtime = lastauthtime " " $1
}

END {
        print "lastauthtime::" lastauthtime
}' file

which produces the output:

Code:

lastauthtime:: steve rob matt

Or, more simply (and, perhaps, with less confusing names):

Code:

awk '
BEGIN {
	FS = "="
        RS = ""
}

NF==2 {
        noauthtime = noauthtime " " $2
}

END {
        print "noauthtime::" noauthtime
}' file

which produces the output:

Code:

noauthtime:: steve rob matt

As always, if you want to use any of these scripts on a Solaris/SunOS system, change awk in these scripts to /usr/xpg4/bin/awk or nawk.