This command prints everything between a line containing "BEGIN" and one containing "END", regardless of what is in between.

Your problem is, if i have understood correctly, is to only print these lines if some condition (a line containing a third word, like "Amit") is met. Here is how you solve these problems with sed:

The first thing you need is: you have to store the text in question somewhere until you decide if you print it or not. For this there is the "hold space". This is a text buffer you can manipulate separately from the "pattern space". It will maintain its content across the processing of lines. See the man page of "sed", the commands "g", "h", "x", "G" and "H". The principle being when you encounter a line with "BEGIN" you start a new cycle: put the encountered line in the hold space. From here on you append every line to there and accumulate the text this way until you encounter a line with "END" in it. When you finally encounter a line with "END" in it you clean out the hold space and start over again.

The second task is to decide if the text should be printed or not: When you encounter a line with END this ends the cycle: move all text accumulated in the hold space back to the pattern space, search the text there for your search string "Amit" and either print the whole text or discard it.

Code:

sed -n '/BEGIN/,/END/H        # from "BEGIN" to "END" execute "H" (append to hold space)
        /END/ {               # for every line containing "END" do:
                 g            # replace the pattern space with the content of the hold space
                              # (that makes the accumulated text available again)
                 /Amit/p      # if in this text is "Amit" somewhere, print it
                 s/.*//       # delete the text
                 x            # exchange pattern- and hold space
                              # (so hold space will be empty for the next cycle)
              }' /path/to/your/file

Or, the same in one line:

Code:

sed -n '/BEGIN/,/END/ H;/END/ {;g;/Amit/p;s/.*//;x;}' /path/to/your/file

I hope this helps.

bakunin

/PS: only now i saw that Anbu23 has already posted a sed solution which works the same way. My script and his second solution are quite similar but his way of cleaning the hold space is better than mine, so i suggest you use his.