awk     'FNR==1         {FILE++}

         FILE==1        {CHR[$1]=$2
                         POS[$1]=$3
                         next
                        }

         FILE==2        {S2[$1]=$0
                         next
                        }

         FILE==3        {if (FNR==1)    {for (i=2; i<=NF; i++) S[i-1]=$i
                                         next
                                        }
                         M[$1]
                         for (i=2; i<=NF; i++)  {S1[$1,S[i-1]]=$i
                                                 total[$1]++
                                                 if ($i == "-")  missing[$1]++
                                                 else           {data[$1]++
                                                                 C1=substr($i,1,1)
                                                                 C2=substr($i,2,1)
                                                                 GN[C1]
                                                                 GN[C2]
                                                                 if (C1 == C2)  {mono[$1]++
                                                                                 G[$1,C1]+=2
                                                                                }
                                                                 else           {mixed[$1]++
                                                                                 G[$1,C1]++
                                                                                 G[$1,C2]++
                                                                                }
                                                                }
                                                }
                        }

         END            {printf "%-40s", "NAME"
                           for (m in M) printf "\t%s", m
                           printf "\n"
                         printf "%-40s",  "CHR"
                           for (m in M) printf "\t%s", CHR[m]
                           printf "\n"
                         printf "%-40s",  "POS"
                           for (m in M) printf "\t%s", POS[m]
                           printf "\n"

                         for (g in GN)  {printf  "%-40s", g
                                           for (m in M) printf "\t%s", G[m, g]+0
                                           printf "\n"
                                        }

                         printf  "%-40s", "-"
                           for (m in M) printf "\t%s", missing[m]+0
                           printf "\n"

                         printf "m"
                           printf "\n"

                         printf  "%-40s", "data"
                           for (m in M) printf "\t%s", data[m]+0
                           printf "\n"

                         printf  "%-40s", "mono"
                           for (m in M) printf "\t%s", mono[m]+0
                           printf "\n"

                         printf  "%-40s", "mixed"
                           for (m in M) printf "\t%s", mixed[m]+0
                           printf "\n"

                         printf  "%-40s", "total"
                           for (m in M) printf "\t%s", total[m]+0
                           printf "\n"

                         for (s in S)   {printf  "%-40s", S2[S[s]]
                                           for (m in M) printf "\t%s", S1[m, S[s]]
                                           printf "\n"
                                        }
                        }
        ' lookup1 lookup2 matrix
NAME                                        M1    M2    M3
CHR                                         chr7    chr8    chr7
POS                                         28.9    129.678    4.456
A                                           4    4    0
G                                           0    4    2
T                                           2    0    2
-                                           1    0    2
m
data                                        3    4    2
mono                                        3    2    2
mixed                                       0    2    0
total                                       4    4    4
S1 GGHBBGG/DEDD(@DCCD)                      AA    AG    GG
S2 GGHBBGG/DEDD(@DCCD)//B-                  AA    AG    TT
S3 GGHBBGG/DEDD(@HH?)//B1@NNN               TT    AA    -
S4 GGHBBGG/DEDD(@DCCDH)#-BCF1               -    GG    -