awk '
BEGIN {	# Set input and output field separators to a tab.
	FS = OFS = "\t"
	# Initialize the table of fields to process (fields[]) and increment the
	# number of Lookup files to expect (nf).
	fields[++nf] = 2	# The 1st Lookup file translates field #2.
	fields[++nf] = 3	# The next Lookup file translates field #3.
	fields[++nf] = 4	# The next Lookup file translates field #4.
}
# If this is the 1st line in a file...
FNR == 1 {
	# increment the input file number.
	f++
}
# If we are looking at a line from a Lookup file...
f <= nf {
	# set the lookup table (l[]) entry for this file (f) and input value
	# ($1) to the corresponding subfield data to be added ($2).
	l[f, $1] = $2
	# Skip to next input line and do not perform the following actions...
	next
}
# If we get to this point, we have read and accumulated data from all of the
# Lookup files and are now looking at a line from our data file.
{	# Process each field in our table of fields (starting with the last
	# field first).  Note that when we add a tab to a field, the field
	# numbers of following fields will change.
	for(i = nf; i > 0; i--) {
		# Split the selected field into subfields (sf[]) and get the
		# number of subfields to process (n).
		n = split($fields[i], sf, " ")
		# Set the initial contents of the added field data to the output
		# field separator.
		af = OFS
		# For each subfield in this field, append the lookup table value
		# for the entry in the Lookup file corresponding to this field
		# and subfield value, and follow each converted subfield value
		# with a space (for the 1st n-1 subfields) or by nothing (for
		# the lsat subfield).
		for(j = 1; j <= n; j++)
			af = af l[i, sf[j]] ((j < n) ? " " : "")
		# Append the accumulated looked up data to the current field
		# contents.
		$fields[i] = $fields[i] af
	}
}
1	# Print the updated contents of the current data file line.
' Lookup2 Lookup3 Lookup4 file	# Specify the Lookup files and the data file to
				# be processed.