awk '
# This awk script will accumulate STATUS 14 and 98 counts for each ID and
# INDEX given on ocntiguous lines in the input file.  If both STATUS==14
# and STATUS==98 records are found, the ouput order will match the order
# of the 1st appearance of each STATUS value found.  (This script could be
# greatly simplified if the output order could always be the STATUS==14
# count first and the STATUS==98 count second.)

# Function to print STATUS==14 and ==98 data for previous ID and INDEX...
# We have a function here rather than inline code because we need to do
# this when the ID or INDEX changes and when we hit end-of-file.
function pr() {
        # Note that if we are processing the 1st line in the file or if the
        # previous ID and INDEX had no bad STATUS lines, cn will be 0 and the
        # code in the loop will not be executed at all.
        for(i = 1; i <= cn; i++) {
                printf("%s index %d has %d time%s status %d\n",
                        ID, INDEX, c[cc[i]], c[cc[i]] > 1 ? "s" : "",
                        cc[i])
                # We delete individual elements of the c[] because the standard
                # do not currently require that the command "delete array_name"
                # can be used to delete all element of an arry.  We need to
                # remove the entry rather than just set c[x] to zero so we will
                # not print lines showing lines with 0 occurrences of the bad
                # STATUS.
                delete c[cc[i]]
        }
        # Clear the number of types of bad STATUS seen for the next ID + INDEX.
        cn = 0
}
{       # Get ID and INDEX for this line...
        nID = substr($0, 12, 4) substr($0, 20, 4)
        nINDEX = substr($0, 26, 1)
        # If the ID and INDEX on this line do not match the previous line...
        if(nID != ID || nINDEX != INDEX) {
                # Print the results for the previous ID + INDEX
                pr()
                # Set the current ID and INDEX to compare against later lines.
                ID = nID
                INDEX = nINDEX
        }
        # Get the STATUS from this line...
        STATUS = substr($0, 91, 2)
        # If this line has one of the bad STATUS values...
        if(STATUS == 14 || STATUS == 98) {
                # If we have not seen this bad STATUS value for this ID +
                # INDEX...
                if(!(STATUS in c)) {
                        # Increment the number of bad STATUS codes seen (cn)
                        # and set cc[cn] to the bad STATUS code seen on this
                        # line.
                        cc[++cn] = STATUS
                }
                # Increment the number of times we have seen this bad STATUS
                # code for this ID + INDEX.
                c[STATUS]++
        }
}
END {   # Print the results for the last ID + INDEX in the input.
        pr()
}' eff8

Added G1   1234.0  5678.01                                                                14
Added G1   1234.0  5678.01                                                                98
Added G1   1234.0  5678.01                                                                14
Added G2   1111.0  2222.01                                                                98
Added G2   1111.0  2222.01                                                                14
Added G2   1111.0  2222.01                                                                98

31157145 index 3 has 2 times status 14
28037145 index 2 has 2 times status 14
31177140 index 1 has 1 time status 14
31157140 index 2 has 3 times status 98
12345678 index 1 has 2 times status 14
12345678 index 1 has 1 time status 98
11112222 index 1 has 2 times status 98
11112222 index 1 has 1 time status 14