Originally Posted by Don Cragun

Code:

#!/bin/ksh
printf "Enter the date (YYYY/MM/DD): "
read dd
awk -F '[ :]' -v dd="$dd" '
BEGIN { fmt = "Batches that were successful on %s between %02d:%02d:00 " \
                "and %02d:%02d:59 : %d\n"
}
$1 == dd && $NF == "successful" { s[$2 + 0, $3 > 29]++ }
END {   for(h = 0; h < 24; h++)
                 for(m = 0; m < 2; m++)
                        printf(fmt, dd, h, m * 30, h, m * 30 + 29, s[h, m])
}' log

1st line: Use the Korn shell to interpret this script
2nd line: Print a prompt asking the user to input a date.
3rd line: Read the date the user enters and save it in the shell variable named dd.
4th line: Invoke the awk utility telling it to use space and colon characters as field delimiters and define the awk variable dd to have the same value as the shell variable dd.
5th, 6th, and 7th lines: Before any input is read by the awk script, define the awk variable fmt to be the format string we will use to print results in the end.
8th line: If the 1st field on each input file line is the same string as the dd awk variable and the last field on the line is the string "successful", then increment the element of the array s[] indexed by two subscripts (the 2nd field in the line [the hour] with the leading zero removed if there is one, and 0 if the 3rd field in the line [the minute] is less than or equal to 29 or 1 if the minute is 30 or larger).
9th, 10th, and 11th line: After all input lines have been read, loop through every half hour with h set to the hour of the day and m set to the half hour within the hour and print the user entered date (dd), the hour as a two digit string with leading 0 fill, the starting minute as a two digit string with leading 0 fill, the hour again, the ending minute, and the numberer of times the patterns matched on the 8th line were found on lines in the input file within that half hour period.
12 line: Terminate the awk script and specify that the input to be processed is contained in a file named log.