awk '
# Input file format:
#       gid:do_not_care:gname;uname_list
# where:"gid" is a numeric string specifying the group ID number,
#       "do_not_care" is ignored by this script,
#       "gname" is an alphanumeric group name, and
#       "uname_list" is a comma separated list of alphanumeric user names.
#
# The two dimensional array key[] is indexed by the "gid" and a user name.  The
# array starts out empty.  If key[$1, user name] is present, the user name has
# been seen with the "gid" (either earlier on this line or on an earlier line).
# The "gname" is ignored when making this determination, so when we are done, a
# user name will appear only once for each "gid".
BEGIN { # Set the input and output field separators to ":"
        FS = OFS = ":"
}
{       # Split the "uname_list" into n individual user names:
        n = split($4, g, /,/)
        # Update the array of user names seen for this "gid":
        for(i = 1; i <= n; i++)
                # Determine if we have seen this user name with this "gid"
                if(($1,g[i]) in key) {
                        # We have seen this user name with this "gid".  Remove
                        # this name from the list of user names on this line:
                        for(j = i + 1; j <= n; j++) g[j - 1] = g[j]
                        i--     # Repeat the check for user name i.
                        n--     # Decrease the # of user names on this line.
                        c = 1   # Note that we have changed this line.
                } else  # We have not seen this user name with this "gid".
                        # Add an entry for this combination:
                        key[$1,g[i]]
        # Check to see if we need to reformat the "uname_list" (because we
        # removed a user name from the list on this line).
        if(c) { # We do need to reformat the uname_list on this line:
                c = 0     # Clear the flag for the next line.
                # If there are any user names left in the list, initialize the
                # reformatted "uname_list" to the 1st user name that is left;
                # otherwise set the "uname_list" to the empty string.
                # Note that if you want to discard this "gname" if there are no
                # remaining user names in the updated "uname_list", you could
                # do that by replacing the following uncommented line with the
                # next two lines (after removing the "# " in both lines):
                # if(n == 0) next
                # $4 = g[1]
                $4 = n ? g[1] : ""
                # For each additional remaining user name (if any exist), add a
                # comma and that name to the reformatted "uname_list":
                for(j = 2; j <= n; j++) $4 = $4 "," g[j]
        }
        # Print the original or updated line.
        print
}'  data