printf "%d %s\n" 11 3.01234567891E+03 11 123.45678901 5 12345e200 \
5 1234e-200 15 1.23456789012345 4 -123456 11 -123456789012345 |
awk 'function printfEm(value, digits,  exponent, fmt, mantissa, result, sign, spot) {
        # Print a numeric <value> using the format string "%.<digits>E" and 
        # then reformat the result to have a leading 0 instead of a leading
        # non-zero digit.
        # Generate the sprintf() format string and format the given value.
        fmt = sprintf("%%.%dE", digits - 1)
        result = sprintf(fmt, value)
        # Save the sign of the result.
        if(substr(result, 1, 1) == "-") {
                sign = "-"
                # Discard the minus sign...
                result = substr(result, 2)
        } else  sign = ""
        # Find the exponent in the result.
        spot = index(result, "E")
        # Reformat the mantissa.
        mantissa = "0." substr(result, 1, 1) substr(result, 3, spot - 3)
        # Adjust the exponent.
        exponent = substr(result, spot + 1) + 1
        # Return the reformatted sign, mantissa, and exponent.
        return sprintf("%s%sE%+03d", sign, mantissa, exponent)
}
{       printf("Processing \"%%.%dE\" \"%s\"\n", $1, $2)
        printf("%."$1"E\n%s\n", $2, printfEm($2, $1))
}'

Processing "%.11E" "3.01234567891E+03"
3.01234567891E+03
0.30123456789E+04
Processing "%.11E" "123.45678901"
1.23456789010E+02
0.12345678901E+03
Processing "%.5E" "12345e200"
1.23450E+204
0.12345E+205
Processing "%.5E" "1234e-200"
1.23400E-197
0.12340E-196
Processing "%.15E" "1.23456789012345"
1.234567890123450E+00
0.123456789012345E+01
Processing "%.4E" "-123456"
-1.2346E+05
-0.1235E+06
Processing "%.11E" "-123456789012345"
-1.23456789012E+14
-0.12345678901E+15