This will be some work and it is going to become complex. Let us address one problem after the other. I suggest to use sed for this sort of text manipulating tasks.

The general way of addressing this is to retrieve one column after the other, collect the respective info into hold space, finally put the hold space to pattern space and print the line.

We start with trying to find out where a "record" starts by searching for a line with a single number on it. The next line is thought to be a title and the start of a new record. We clear the hold space and then trim the title to a fixed number of characters by first appending x spaces to it, then cutting everything after the first x characters. (I used 20 here, modify it to whatever number you see fit. You will have to change it in both substitute-statements.) Finally collect the title into the hold space:

Code:

sed -n '/^[0-9]$/ {
               n
               s/$/                    /
               s/^\(.\{20\}\).*$/\1/
               x
        }
        x ; s/\n//gp'

Next are the lines with "Pages". We trim the text from them, then pad with spaces like the titles, this time for 15 characters:

Code:

sed -n '/^[0-9]$/ {
               n
               s/$/                    /
               s/^\(.\{20\}\).*$/\1/
               x
               d
        }
        /^Pages/ {
               s/^Pages //
               s/$/               /
               s/^\(.\{15\}\).*$/\1/
               H
        }
        x ; s/\n//gp'

The authors are hard, because we have to imply what the first name and what the family name is. This can't be captured with a simple regexp. If it is always "John Doe" and never "Doe, John" (or vice versa) it is easy to retrieve the first (or second, respectively) name, but if both forms are mixed you will have to correct by hand.

Another thing is that the line with the author names has no distinction. Is it always the line next after the "Pages"-line? If so, the following will work, otherwise i simply see no pattern to match for.

The names handling might need some explanation:

Code:

John Doe, Jane Doe, George Miller

Every last name is followed by a comma or the line end. I substitute therefore a comma at the line end, then throw out every word, which isn't followed by a comma - the "not-last-names".

Code:

John Doe, Jane Doe, George Miller,
Doe,Doe,Miller,
Doe,Doe,Miller
Doe, Doe, Miller

Finally i remove the last comma and add spaces as necessary. Then the column is trimmed to 25 characters and added to the hold space.

Code:

sed -n '/^[0-9]$/ {
               n
               s/$/                    /
               s/^\(.\{20\}\).*$/\1/
               x
        }
        /^Pages/ {
               s/^Pages //
               s/$/               /
               s/^\(.\{15\}\).*$/\1/
               H
               n
               s/$/,/
               s/ *[^ ]*[^,]//g
               s/,$//
               s/,\([^ ]\)/, \1/g
               s/$/                         /
               s/^\(.\{25\}\).*$/\1/
               H
        }
        x ; s/\n//gp'

You should be able to take it from there. Simply retrieve the abstracts text, replace everything between the first two and the last two words with "..." and add this to the hold space, then output the whole.

If you still have troubles ask again and we will go over it again.

I hope this helps.

bakunin