*******************************************************************
        Message name |     Number of errors | Number of unique IPs
*******************************************************************
GENERAL_ERROR_23     |                    1 |                    1
ERROR_22             |                    1 |                    1
INVALID_NUMBER       |                    1 |                    1
FAILURE              |                    5 |                    2
*******************************************************************
           Recharged |      200 |      300 |      500 |     1100
                     |        0 |        1 |        1 |        1
*******************************************************************
test unsuccessful              8
test successful                3
*******************************************************************

#!/usr/bin/awk -f
BEGIN {
        FS=";"
        recharge[200]=recharge[300]=recharge[500]=recharge[1100]=0
}
NF==5 { success++ }
NF>5 { error++; $6=toupper($6); error_by_type[$6]++ }
# count unique ip:error
NF>5 && !ip_err[$6,$2]++ { error_by_ip[$6]++ }
# count recharge
(i=int($4+0.5)) && (i in recharge) { recharge[i]++ }
END {
        # make line separator
        while (length(hr) < 67) hr=hr"*"
        print hr
        printf("%20s | %20s | %20s\n", "Message name", "Number of errors",
                "Number of unique IPs");
        print hr
        for (e in error_by_type)
                printf("%-20s | %20d | %20d\n", e, error_by_type[e],
                        error_by_ip[e])
        print hr
        printf("%20s | %8d | %8d | %8d | %8d\n", "Recharged", 200,300,500,1100)
        printf("%20s | %8d | %8d | %8d | %8d\n", "",
                recharge[200],recharge[300],recharge[500],recharge[1100])
        print hr
        printf("%-30s %-6d\n", "test unsuccessful ", error)
        printf("%-30s %-6d\n", "test successful ", success)
        print hr
}