#
function setFieldsByWidth(   i,n,start,copyd0) {
  # Licensed under GPL Peter S Tillier, 2003
  # NB corrupts $0
  copyd0 = $0                             # make copy of $0 to work on
  if (length(FIELDWIDTHS) == 0) {
    print "You need to set the width of the fields that you require" | stderr
    print "in the variable FIELDWIDTHS (NB: Upper case!)" | stderr
    exit(1)
  }

  if (!match(FIELDWIDTHS,/^[0-9 ]+$/)) {
    print "The variable FIELDWIDTHS must contain digits, separated" | stderr
    print "by spaces." | stderr
    exit(1)
  }

  n = split(FIELDWIDTHS,FWS)

  if (n == 1) {
    print "Warning: FIELDWIDTHS contains only one field width." | stderr
    print "Attempting to continue." | stderr
  }

  start = 1
  for (i=1; i <= n; i++) {
    $i = substr(copyd0,start,FWS[i])
    start = start + FWS[i]
  }
}

#I then call setFieldsByWidth() in my main awk code as follows:

BEGIN {
  FIELDWIDTHS="2 5 2 4 8 2 4 5" # for example
  stderr="cat 1>&2"
}
!/^[  ]*$/ {
  saveDollarZero = $0 # if you want it later
  setFieldsByWidth()
  formatF2= "%0" FWS[2] "d"
  formatREST= "%0" length(saveDollarZero) - FWS[1] - FWS[2] "d" "\n"
  # now we can manipulate $0, NF and $1 .. $NF as we wish
  $2=sprintf(formatF2, $2 - $8)
  printf("%s", $1 $2)
  printf(formatREST, 0)
  # second line
  $2=sprintf(formatF2, $8)
  printf("%s", $1 $2 $3 $4 $5)
  formatREST= "%0" length(saveDollarZero) - FWS[1] - FWS[2] - FWS[3] - FWS[4] - FWS[5] "d" "\n"
  printf(formatREST, 0)
}