UNIX for Dummies Questions & Answers

ps -ef:

UID PID PPID C STIME TTY TIME CMD
root 1 0 0 May26 ? 00:00:07 init
root 2 1 0 May26 ? 00:00:00 [keventd]
root 3 1 0 May26 ? 00:00:00 [kapmd]
root 4 1 0 May26 ? 00:00:00 [ksoftirqd_CPU0]
root 5 1 0 May26 ? 00:00:16 [kswapd]
root 6 1 0 May26 ? 00:00:00 [bdflush]
root 7 1 0 May26 ? 00:00:00 [kupdated]

BEGIN {
  # save the default awk FieldSeparator by default FS is " " [simplified]
  FSorig=FS
  
  # reset the FieldSeparator to ":" - the field separator of '/etc/passwd'
  FS=":"
  passwd="/etc/passwd"

  # read the content of the '/etc/passwd' into awk associative array
  # indexed by the FIRST field of '/etc/passwd' [UID] with the value
  # of the FIFTH field [full user name]
  while (getline < passwd > 0 )
     arrPWD[$1] = $5

  # reset the FieldSeparator to its original value [" "]
  FS=FSorig
}

# save the the FIRST line of the input [ps -ef] as a 'header'.
FNR==1 { header=$0; next }

# for the 'other' lines build up the array ['arr'] indexed by the FIRST column 
# of the input [UID] with the content of the EVERY record/line of the input
# [ps -ef]. The lines with the same UID [first field - $1] are concatinated with
# 'SUBSEP' in between te strings.
{ arr[$1] = ($1 in arr) ? arr[$1] SUBSEP $0 : $0 }

# After ALL the input lines [from 'ps -ef'] are processed - print out
END {
   # iterate trough the array build based on the input ['ps -ef'] above
   # The iterator [i] is the FIRST field in 'ps -ef'
   for ( i in arr ) {

       # given the iterator [UID] - look it up in the array built based on the 
       # content of '/etc/passwd'.
       # This outputs the UserName and the Header line from 'ps -ef'
       printf("%s\n\t%s\n", arrPWD[i], header)

       # deconstruct the content of the arr[i] - it's a concatination of ALL
       # the lines ['ps -ef'] for a user [current itertator 'i']. The result is an
       # array 'procA' with 'n' entries.
       n=split(arr[i], procA, SUBSEP)

       # iterate through the procA array outputing all cells.
       for(y=1; y <= n ; y++)
          printf("\t%s\n", procA[y])
  }
}