UNIX for Dummies Questions & Answers

Hi all,

How can i display the middle line of a file using a single line command?

Code:

awk '{a[b++]=$0;}END{print a[int(b/2)];}' infile

Can you please explain this part "{a[b++]=$0;}" of the code.
Im new to Unix.

The b variable, incrementing on every line, is identical with awk's NR variable.
So one can shorten it to

Code:

awk '{a[NR]=$0;} END {print a[int(NR/2)]}' infile

a is an array that stores each line.
So the file must fit into memory!
At the END, the middle array element is printed.
Another approach, slower but saving memory is

Code:

awk 'int((NR-FNR)/2)==FNR {print; exit}' infile infile

also using another awk variable FNR, but needs to read infile twice.
The difference between NR and FNR might become clear with the following test

Code:

awk '{print "NR="NR, "FNR="FNR, $0}' infile infile

And by looking at it, or by applying school mathematics one can optimize to

Code:

awk 'NR==FNR*3 {print; exit}' infile infile

Unfortunately, if infile contains an odd number of lines (3 for example), none of these will work.
In the 1st awk script int(3/2) is 1, not 2; so that script prints the 1st line instead of the 2nd (middle) line in the file.
And, in the 2nd awk script, the line to be printed from the file reading it the 2nd time would have NR == 5 and FNR == 2, but NR (5) != FNR*3 (6).

A corrected version of the 1st script should work (as long as the file fits in memory):

Code:

awk '{a[NR]=$0} END {print a[int((NR+1)/2)]}' infile

The simplest working code I came up with reading the file about 1.5 times is:

Code:

awk '
FNR == 1 && NR != 1 {x = int(NR/2)}
FNR == x {print;exit}
' infile infile

Thanks for the finding.
Then, for esthetic reasons, I prefer

Code:

awk '(FNR==1) {x=int(NR/2)} (FNR==x) {print; exit}' infile infile

Thank you soo much @MadeInGermany and @Don Cragun.