Login or Register to Ask a Question and Join Our Community


UNIX for Dummies Questions & Answers

Converting Columns To Rows Sort Of

 
Thread Tools Search this Thread
Top Forums UNIX for Dummies Questions & Answers Converting Columns To Rows Sort Of
# 1  
Old 05-24-2013
Converting Columns To Rows Sort Of
Hi I'm a UNIX awk and sed novice at best. I'm trying to creat a .csv file so it can be graphed in Excel. Tried various xargs, awk, sed and paste but just can't seem to get the data to line up. Not sure if this is beyond for a question in these forums. Any help would greatly be appreciated.
Code:
Have this:
May1 Mary 100
May2 Mary 200
May3 Mary 300
May1 Jimmy 150
May2 Jimmy 200
May3 Jimmy 400
 
Would like this:
           May1  May2   May3
Mary      100     200     300
Jimmy     150     200     400

# 2  
Old 05-24-2013
Are you trying to create a CSV from your input file that you can use as input to Excel, or do you want an awk program that will produce the table you showed at the end of your post with the output columns nicely lined up?
# 3  
Old 05-24-2013
Hey Don, trying to get an awk script to create the .cvs file.
# 4  
Old 05-25-2013
The following awk script will do both. The standard output from this script will be a formatted table and another file (named input_file_name.csv) will be created that is a comma separated values file that can be input to Excel. With the script:
Code:
awk '{  if(!($1 in w)) {
                c[++cc] = $1
                w[$1] = length($1)
        }
        if(!($2 in rv)) {
                r[++rc] = $2
                rv[$2]
                if(length($2) > w[0]) w[0] = length($2)
        }
        d[$2,$1] = $3
        if(length($3) > w[$1]) w[$1] = length($3)
}
FNR == 1 {f = FILENAME ".csv"}
END {   # Create the formatted table output directly:
        # Print heading line.
        printf("%*s", w[0], "")
        for(i = 1; i <= cc; i++) printf("%*s", ++w[c[i]], c[i])
        printf("\n")
        # Print data lines.
        for(i = 1; i <= rc; i++) {
                printf("%*s", -w[0], r[i])
                for(j = 1; j <= cc; j++)
                        printf("%*s", w[c[j]], d[r[i], c[j]])
                printf("\n")
        }
        # Create .csv file for input to Excel.
        # Print heading line.
        for(i=1; i <= cc; i++) printf(",%s", c[i]) > f
        printf("\n") > f
        # Print data lines.
        for(i = 1; i <= rc; i++) {
                printf("%s", r[i]) > f
                for(j = 1; j <= cc; j++) printf(",%s", d[r[i], c[j]]) > f
                printf("\n")  > f
        }
}' input

(NOTE: If you are using a Solaris/SunOS system, use /usr/xpg4/bin/awk, /usr/xpg6/bin/awk, or nawk instead of awk.)
If the file inputcontains:
Code:
May1 Mary 100
May2 Mary 200
May3 Mary 300   
May1 Jimmy 150  
May2 Jimmy 200
May3 Jimmy 400
May4 Mary 1     
May4 Jimmy 2    
May4 extra 100000000
May5 Mary 3
May5 Jimmy 4
M6 extra 5

the following table will be written to standard output:
Code:
      May1 May2 May3      May4 May5 M6
Mary   100  200  300         1    3   
Jimmy  150  200  400         2    4   
extra                100000000       5

and the following will be written to a file named input.csv:
Code:
,May1,May2,May3,May4,May5,M6
Mary,100,200,300,1,3,
Jimmy,150,200,400,2,4,
extra,,,,100000000,,5

This User Gave Thanks to Don Cragun For This Post:
jimmyf
# 5  
Old 05-25-2013
Brilliant, Don. Thank you!
 
Login or Register to Ask a Question

Previous Thread | Next Thread

10 More Discussions You Might Find Interesting

1. Shell Programming and Scripting

Converting columns of text to rows, with blank lines

I've spent the past hour trying different things and googling for this solution and cannot find the answer. Found variations of this, but not this exact thing. I have the following text, which is the output from our mainframe. Each field is on a separate line, with a blank line between each... (7 Replies)
Discussion started by: lupin..the..3rd
7 Replies

2. Shell Programming and Scripting

Converting rows into columns

hi all I need a help ..I have a script that takes has command and its output is like below.. a b a v v a c I am assigning the above outputs to a variable .. <variable name> = <command output> problem here is when I echo the variable ..it gives me output like " a b... (3 Replies)
Discussion started by: shankarb
3 Replies

3. UNIX for Dummies Questions & Answers

Converting txt output to rows and columns and send report via mail.

Hi All, I would like to send below output in a tabular column ( xml or excel ) and send a mail. vinay unix anil sql vamsee java request to suggest a solution. (1 Reply)
Discussion started by: Girish19
1 Replies

4. Shell Programming and Scripting

Deleting all the fields(columns) from a .csv file if all rows in that columns are blanks

Hi Friends, I have come across some files where some of the columns don not have data. Key, Data1,Data2,Data3,Data4,Data5 A,5,6,,10,, A,3,4,,3,, B,1,,4,5,, B,2,,3,4,, If we see the above data on Data5 column do not have any row got filled. So remove only that column(Here Data5) and... (4 Replies)
Discussion started by: ks_reddy
4 Replies

5. Shell Programming and Scripting

Converting rows to columns in csv file

Hi, I have a requirement to convert rows into columns. data looks like: c1,c2,c3,.. r1,r2,r3,.. p1,p2,p3,.. and so on.. output shud be like this: c1,r1,p1,.. c2,r2,p2,.. c3,r3,p3,.. Thanks in advance, (12 Replies)
Discussion started by: Divya1987
12 Replies

6. Shell Programming and Scripting

Converting rows to columns using shell script

I have a script which converts rows to columns. file_name=$1 mailid=$2 #CREATE BACKUP OF ORIGINAL FILE #cp ${file_name}.xlsx ${file_name}_temp.xlsx #tr '\t' '|' < ${file_name}_temp.xlsx > ${file_name}_temp.csv #rm ${file_name}_temp.xlsx pivot_row=`head -1 ${file_name}` sed 1d... (3 Replies)
Discussion started by: andy538
3 Replies

7. Shell Programming and Scripting

converting rows into columns

Hi, I am trying to fetch some values from db and spooling the output to a file. when i query the db for the values, i get the values in following format. PC_1 wf_test1 Test PC_2 wf_test2 Test PC_3 wf_test3 Test But my spool file was created in following format. PC_1 wf_test1 Test... (20 Replies)
Discussion started by: svajhala
20 Replies

8. UNIX for Dummies Questions & Answers

Converting columns into rows

Is there anyway to convert columns into raws using awk? (or any other command line):eek::eek::eek::eek::eek::eek::eek::eek::eek: (1 Reply)
Discussion started by: cosmologist
1 Replies

9. UNIX for Dummies Questions & Answers

Converting rows into multiple-rows

Hi every one; I have a file with 22 rows and 13 columns which includes floating numbers. I want to parse the file so that every five columns in the row would be a new record (row). For example, the first line in the old file should be converted into three lines with first two lines contain 5... (6 Replies)
Discussion started by: PHL
6 Replies

10. Shell Programming and Scripting

how to converting rows to columns, bash

I have in file these words: @fraza1 = rw @fraza2 = r @fraza3 = r @fraza4 = r @fraza5 = r @fraza1 = r @fraza6 = r @fraza7 = r @fraza2 = r @fraza8 = r @fraza9 = r ... I would like so that: ,rw,@fraza1 ,r,@fraza2 (2 Replies)
Discussion started by: patrykxes
2 Replies
Login or Register to Ask a Question