UNIX for Dummies Questions & Answers

# create two hashes (min and max) based on the contents of the nineth field ($9)
awk '
    {       # this block of code executed for each input record
        min[$9] = min[$9] ? min[$9] : $4;       # capture field 4 as initial default if min is not set
                                                # this assumes that values in field 4 will always be non-zero

        # max does not need to be initialised as it defaults to zero.  (provided field 5 values are always >= 0)

        min[$9] = $4 < min[$9] ? $4 : min[$9];  # capture current field 4 if it is smaller than minimum
        max[$9] = $5 > max[$9] ? $5 : max[$9]   # capture field 5 if larger than maximum
    }

    # this code block executed after last input record  has been read and processed above
    # the assumpion that the last input record is still in the buffer (might not be true for old awk versions, 
    # but this is not likely to be an issue.  The programme also assumes that the only changing fields
    # in the input data are fields 4, 5, and 9.
    END {
        for (i in max)  # for each value of field 9 that was observed
        {
            $4=min[i];      # substitute the min and max values and field 9 into the current record.
            $5=max[i];
            $9=i;
            print           # print the record with the substituted values.
        }
    }'