UNIX for Dummies Questions & Answers

Hello everyone

I could really need some help. I want to rename : with dot. But the problem is that i don't want to touch the hours like 12:00 but i want to change AD:FG with AD.FG. I'm thinking something like [A-Z]: to [A-Z].

I don't know if i explain it corrrectly but i could use some help

Thanks in advance

The basic pattern for sed substitutions is:

Code:

s[delimiter]<pattern>[delimiter]<replacement pattern>[delimiter]<options>

The delimiter is any single character, you just have to use the same throughout the command. Traditionally the slash ("/") is used, but you could use any other either. The "pattern" is what you look for, the "replacement pattern" is what you want to replace it with.

Per default only the first occurrence ina line is replaced, if you want to change every occurrence of the pattern in a line you have to add the option "g" (for "global").

As an example: change the first "a" to "b" ("aaaaa" will become "baaaa"):

Code:

s/a/b/

change every "a" to "b":

Code:

s/a/b/g

It would be easy to apply this to your problem and write as a search pattern: "[A-Za-z]:". Unfortunately things are a litle bit more complicated: we will have to "remember" in the replacement pattern which character we have matched in the search pattern. "A:" should be replaced by "A.", but "B:" by "B.", etc.

There is a device in sed which can accomplish this. It is like defining a variable and using its content in the replacement pattern: The parts in the search pattern we enclose in "\(" and "\)" are being remembered and we can use "\1" ("\2", ...) in the replacement pattern to call these.

Here is an example:

Code:

s/\([A-Za-z]\)/=\1=/g

every single character is replaced by itself, surrounded by equal signs. Input: "a b c d" Output: "=a= =b= =c= =d=".

Applying this to your problem:

Code:

s/\([A-Za-z]\):/\1./g

I hope this helps.

bakunin

Thanks for the quick answer but it doesn't work.

i run

Code:

sed -i -e s/\([A-Za-z]\):/\1./g

but didn't change. In order to be sure that i explained it correctly and don't eat your time for nothing, i want to change OD:OD to OD.OD but not touch 12:00 that is in a previous line

Thanks again

Hmm...

Your command looks good, but i miss quoting: many of the characters used in sed-expressions are special to the shell and therefore it is very advisable to enclose EVERY sed-statement in single quotes:

Code:

sed 's/\([A-Za-z]\):/\1./g' /path/to/inputfile

Issue the statement as it is, it will display its results on screen (you might pipeline it to "more" to read it). Once you are satisfied with the results redirect the output to another(!) file, then "mv" the output over the original input.

Using "-i" is an extremely dangerous options, because if the sed statement does something other than expected your input file will be corrupted.

I hope this helps.

bakunin

Code:

$ echo "12:00 but i want to change AD:FG with AD.FG" | sed 's/\([[:alpha:]]\):/\1./g'
12:00 but i want to change AD.FG with AD.FG

You absolutely correct .it works but i must find a way to make it work with unicode. I use cygwin to test it, but because the characters are in greek i could get the correct result. So i tested in shell like that

Code:

echo "12:00 OD:OD") | sed 's/\([A-Za-z]\):/\1./g'

and worked. Now i have to see how to make it work from batch using greek letters.

Anyway, thanks for the time and the correct answer

You could alternately use the negation of digit :

Code:

$ echo "12:00 OD:OD" | sed 's/\([^0-9]\):/\1./g'
12:00 OD.OD
$ echo "12:00 OD:OD" | sed 's/\([^[:digit:]]\):/\1./g'
12:00 OD.OD