UNIX for Advanced & Expert Users

Hello All,

My requirement is to get test between two words START & END, something like html tags
Eg. Input file:
START
Line1
Line2
Line3
CLOSE

START
Line4
Line5
Line6
END

START
Line7
START
Line8
END
Line9
END

Output Required:
START
Line4
Line5
Line6
END

START
Line8
END

START
Line7
Line9
END

The order of the two output blocks can change. That is not a problem.


Thanks and Regards,
Suneel C Koneru.

This may be difficult without more information. You first have a START tag without an END. How do you know not to continue until reaching the end of file? Do you reset at a blank line?

---------- Post updated at 07:41 AM ---------- Previous update was at 07:22 AM ----------

I was able to recreate your output:

Code:

mute@eeepc:~$ ./tags file
START
Line4
Line5
Line6
END

START
Line8
END

START
Line7
Line9
END

mute@eeepc:~$

I create this awk program and comment it to help. This does not reset on blank line as I asked previously. In fact if you add a matching END tag to end of file, you'll get the elements which were not yet printed..

Code:

#!/usr/bin/awk -f

# p=print, counts the "block" we are in
# c[p] then is the record number (line count) within that block
$0 == "START" {p++; c[p]=0}

# if we reach END and are within a block, print out each stored record
$0 == "END"&&p {
	for (i=0;i<c[p];i++)
		print a[p,i]
	# in case of a nested block, we'll need to decrement to continue
	# capturing for it
	p--
	print $0 "\n"	# print END, and extra newline
	next		# don't process this line any further
}
# if in a block, store it in our array
p { a[p,c[p]++] = $0 }

If this is to be embedded in sh script, of course you can condense the code:

Code:

awk '/^START$/{p++;c[p]=0}/^END$/&&p{for(i=0;i<c[p];i++)print a[p,i];p--;print $0 RS;next}p{a[p,c[p]++]=$0}' file

kudos to you Scott....... this is absolutely what I wanted.......
First block of lines 1, 2 & 3 was required to be omitted.........

thank you very very much.......
You saved my day.........

- Suneel

---------- Post updated at 06:29 PM ---------- Previous update was at 06:24 PM ----------

Can this be modified to use with any combination of upper or lower case letters given in the input file and return the output ............?

you mean instead of START you can have Start, etc? This is not pretty in awk:

Replace either

Code:

$0 == "START"

with

Code:

toupper($0) == "START"

OR

Code:

/^[Ss][Tt][Aa][Rr][Tt]$/

I now tried your code which you have put in "tags" file and I get error
> sh -x tags.sh test.txt
+ tags.sh == START '{p++'
tags.sh: line 5: tags.sh: command not found
+ c[p]='0}'
+ tags.sh == END
tags.sh: line 8: tags.sh: command not found
tags.sh: line 9: syntax error near unexpected token `('
tags.sh: line 9: ` for (i=0;i<c[p];i++)'


> cat tags.sh
#!/bin/bash
#!/usr/bin/awk -f

# p=print, counts the "block" we are in
# c[p] then is the record number (line count) within that block
$0 == "START" {p++; c[p]=0}

# if we reach END and are within a block, print out each stored record
$0 == "END"&&p {
for (i=0;i<c[p];i++)
print a[p,i]
# in case of a nested block, we'll need to decrement to continue
# capturing for it
p--
print $0 "\n" # print END, and extra newline
next # don't process this line any further
}

I'm running suse linux with /bin/bash

That entire file is an awk program. Notice the #!/usr/bin/awk -f already on the first line.
You can:

Thanks buddy........ sometimes brain doesn't just work for even small things when I struggle with bigger things............

anyways.......... thank u very much..........