UNIX and Linux Applications

65005
65007
65006
27117
68700
68399

col1        col2     col3
65005    65008    A
68399    68399    A
68700    68700    A
22980   22999     B
27109    27125    C

col3  Count
A        5
B        0
C        1

awk 'FNR==NR{range[$1,$2]=$3;next}
{
for(i in range)
{
 c[range[i]]+=0
 split(i,r,SUBSEP)
 if($1>=r[1] && $1<=r[2])
  c[range[i]]++
}
}
END{
for(i in c)
print i,c[i]|"sort"}' file2 file1

cat file1
65005
65007
65006
27117
68700
68399

cat file2
65005 65008 A
68399 68399 A
68700 68700 A
22980 22999 B
27109 27125 C

awk 'FNR==NR{range[$1,$2]=$3;next}
> {
> for(i in range)
> {
>  c[range[i]]+=0
>  split(i,r,SUBSEP)
>  if($1>=r[1] && $1<=r[2])
>   c[range[i]]++
> }
> }
> END{
> for(i in c)
> print i,c[i]|"sort"}' file2 file1
A 5
B 0
C 1

awk '<program>' /path/to/file2 /path/to/file1

awk '
### THIS STORES THE RANGES FROM THE FIRST FILE ON THE COMMAND LINE (file2) ###
### IN AN ARRAY IN MEMORY. REQUIRED FOR LOOKUP LATER WHEN WE START READING ###
### file1.                                                                 ###
FNR==NR{range[$1,$2]=$3;next}
##############################################################################
{
### FOR EACH LINE FROM file1, THIS LOOPS THROUGH THE ARRAY STORED IN MEMORY###
### AND CHECKS IF THE LINE READ IS IN ANY OF THE RANGES. IF YES, THE COUNT ###
### OF THE RANGE NAME (A,B,C,D,ETC.) IS INCREMENTED BY ONE.                ###
for(i in range)
{
 c[range[i]]+=0
 split(i,r,SUBSEP)
 if($1>=r[1] && $1<=r[2])
  c[range[i]]++
}
###############################################################################
}
### THIS IS DONE AFTER READING THE 2 FILES COMPLETELY. THIS SIMPLY PRINTS   ###
### THE ARRAY INDEX (RANGE NAME) AND THE CORRESPONDING VALUE (COUNT). THE   ###
### OUTPUT IS PIPED TO THE SORT COMMAND TO GET THE OUTPUT DESIRED.          ###
END{
for(i in c)
print i,c[i]|"sort"}
################################################################################
' file2 file1