Shell Programming and Scripting

hello all,
I have a file like this:

Code:

section 1
blah1
blah2
section 2
blah1
blah2
section 3
blah1
blah2

and I want to use sed to duplicate section 2, like this:

Code:

section 1
blah1
blah2
section 2
blah1
blah2
section 2
blah1
blah2
section 3
blah1
blah2

I've figured out that I can do this:

Code:

sed -n '/section 2/,/section/{ p }' input_file

and it will return:

Code:

section 2
blah1
blah2
section 3

but I can't get it to drop the last line, and I can't get my regexp to say grab UNTIL you get to the word section, since thats marking the line. Help please, I've been reading the sed tutorials and man pages endlessly and now I'm just going in circles.

The real hurdle is in expressing more complex logic than "from here through to here". But sed is a programming language, just rather primitive, and very terse (or "succinct", or "unreadable", depending on how you look at it).

So to paraphrase, between section 2 and section 3, you want to print, but not if it's section 3. If expressed this way, it's easy (just not very elegant):

Code:

sed -n '/section 2/,/section 3/{;/section 3/!p;}' input_file

Incidentally, in your original script, the braces were not necessary, but now they are, because there's a block of multiple things we want to happen when the first condition matches.

Just to complete it, why don't you collect section 2 into the hold space, and print it out a second time when you see the section 3 heading:

Code:

sed '/section 2/,/section 3/{;/section 3/!{;H;b;};x;D;p;x;}' input_file

So if we are between section 2 and section 3 (inclusive); then if we are not looking at section 3, append to hold space, and skip to the end of the current script (where the line is implicitly printed the first time); else, recall what's in the hold space, remove the first item (which is empty, because we have been appending to the hold space, and that's what it originally contained), print, and recall back the earlier pattern space (which is the section 3 heading; again, at the end of the script, that line is printed.

This would be way more readable and maintainable in awk or Perl, mind.

Code:

awk '
/section 2/ {f=1}
/section 3/{
  f=0; 
  for(i=1;i<=c;i++) print a[i]  
}
f{ print; a[++c]=$0 }
!f{ print}
' file