Shell Programming and Scripting

I've 3 data files as below,
In each file first line-first letter 'H' indicates the header,
'0' and '9' indicates the data record in which 0 for credit and 9 for debit.
Also from the position 5-6 we have this credit/debit amount values.

In last line, 'T' indicates the 'trailer record'. second field indicates the
number of debit 'data record' and third field indicates the the number of
credit 'data record'. fourth field indicates 'sum value of debit' and last field
indicates 'sum value of credit'.

file1.txt

H0000000000001
9abc20gfhxyzer
0mnw10dcspreer
9lst70axrstrqw
9lkd20trqeretr
0dre60abcwerip
0ter20kdjjfkjk
T 03 03 110 90

file2.txt

H0000000000001
9abc20gfhxyzer
0mnw10dcspreer
9lst70axrstrqw
9lkd20trqeretr
0dre60abcwerip
T 03 02 110 70

file3.txt

H0000000000001
9abc20gfhxyzer
0mnw10dcspreer
0lst70axrstrqw
9lkd20trqeretr
0dre60abcwerip
T 02 03 40 140


From the above files Iam creating one out file "outfile.txt" as below:

printf"H0000000000001" > outfile_header.txt ##Header record

## Selecting the data record
nawk '
/^[0-9]/ { print $0 }
' $cur_file >> outfile_data.txt ##Data records

Now the problem Iam facing is to create the trailer for the 'output.txt'.
How to calculate the sum/total of debit and credit from the created 'outfile_data.txt'.


please help me / Lokiman

Could you post the desired result,
given the content of file*.txt you posted?

outfile.txt should be:

H0000000000001 ##Header
9abc20gfhxyzer
0mnw10dcspreer
9lst70axrstrqw
9lkd20trqeretr
0dre60abcwerip
0ter20kdjjfkjk
9abc20gfhxyzer
0mnw10dcspreer
9lst70axrstrqw
9lkd20trqeretr
0dre60abcwerip
9abc20gfhxyzer
0mnw10dcspreer
0lst70axrstrqw
9lkd20trqeretr
0dre60abcwerip
T 08 08260 300 # Trailer

It should include all the data records from the above 3 files.

The trailer should contain, number of debit records (08)- starting with '9',
number of credit records (08)- starting with '0' , total for debit (260) and credit (300) records.

Also I've to compare (validate) the sum of all trailer record values for the above with the 'output.txt'
trailer values.

Code:

awk '
END { printf "T %02d %02d %02d %02d\n", dc, cc, d, c 
if ((dc FS cc FS d FS c) == (dct FS cct FS dt FS ct))
  print "Trailers are correct." > "/dev/stderr"
else
  print "Trailers are wrong!" > "/dev/stderr" }
/^T / { split($0,t," "); dct += t[2]; cct += t[3]; dt += t[4]; ct += t[5]; next }
/^9/ { dc ++; d += $2 } /^0/ { cc ++; c += $2 } NR == 1 || FNR > 1
' FS="[a-z][a-z][a-z]" file* > output.txt

Use nawk or /usr/xpg4/bin/awk on Solaris.

Thanks a crore Genius,

Also special thanks for your interest on such a fresher like us.

With Regards / Lokiman

One important requirement. I want to read the variable values which are declared inside the 'awk' script from the outside.

pls consider the below script:

#!/usr/bin/ksh

nawk '
BEGIN{
v_num_zero=0;
v_sum_zero=0;
v_num_nine=0;
v_sum_nine=0;
}

{
}

/^0/ {
v_num_zero++;
cur_zero=substr($0,5,2);
v_sum_zero=v_sum_zero+cur_zero;
}

/^9/ {
v_num_nine++;
cur_nine=substr($0,5,2);
v_sum_nine=v_sum_nine+cur_nine;
}

END {
printf "Number of Zeros are: %d\n",v_num_zero;
printf "Sum of Zeros are : %d\n",v_sum_zero;
printf "Number of Nines are: %d\n",v_num_nine;
printf "Sum of Nines are : %d\n",v_sum_nine;
} ' a.txt

echo $v_num_zero
echo $v_sum_zero
echo $v_num_nine
echo $v_sum_nine

I want to read the variable values 'v_num_zero', 'v_sum_zero', 'v_num_nine',
'v_sum_nine' for future use.

can you suggest some idea on this...?

Hm, something ugly like this:

Code:

eval "$(nawk '
/^0/ {
v_num_zero++;
v_sum_zero+=$2;
}
/^9/ {
v_num_nine++;
v_sum_nine+=$2;
}
END {
print"v_num_zero="v_num_zero,"v_sum_zero="v_sum_zero,
"v_num_nine="v_num_nine,"v_sum_nine="v_sum_nine
}' FS="[a-z][a-z][a-z]" file*)"

For example:

Code:

$ eval $(nawk '
/^0/ {
v_num_zero++;
v_sum_zero+=$2;
}
/^9/ {
v_num_nine++;
v_sum_nine+=$2;
}
END {
print"v_num_zero="v_num_zero,"v_sum_zero="v_sum_zero,
"v_num_nine="v_num_nine,"v_sum_nine="v_sum_nine
}' FS="[a-z][a-z][a-z]" file*)
$ set|fgrep v_
_=v_sum_nine=260
v_num_nine=8
v_num_zero=8
v_sum_nine=260
v_sum_zero=300