Shell Programming and Scripting

how to get the column names and values after the || del.
i tried like this ..grep '||' file name | grep -v '_' | grep -v base | awk '{print $3, $4 } i'm get the values but the column names.
________________________
|| Base Compare
dept_nub || COL1 COL1
|| _EXIT_DT _EXIT_DT
||
_________|| _________
41041 || 17303 5
41042 || 17303 0

values for the columns
________________________
|| Base Compare
dept_nub || rate_hi rate_hi
||
_________|| ________________
l0510210 || 100.00 34
51031 || 17.0 21
510410 || 17303 0

With your data example, show us the result that you are expected for (with some explanations).

Jean-Pierre.

need to load these all colum difference into tbl so expected output like this below.

col1_exit_dt,17303,5
col1_exit_dt,17303,0
rate_hi,100,34

thanks for your time.

Your explanations are a little short.
A possible solution (that can be simplified i think, but i'm not sure that the result is what you are expected for) :

Code:

#!/usr/bin/awk -f
# Awk File: extract.awk

BEGIN {
   FS  = "|";
   OFS = ",";
}

($0 ~ /^_+$/),(NF==3 && $1 ~ /^_+ *$/) {
   if ($0 ~ /^_+$/) {
      column_name = "";
      next;
   }
   if ($3 ~ /^ *__+/)        next;
   if ($3 ~ /Base Compare/) next;
   sub(/^[[:space:]]*/,  "", $3);
   sub(/[[:space:]]+.*/, "", $3)
   column_name = column_name $3
   next;
}
NF == 3 {
   sub(/^[[:space:]]*/,  "", $3);
   sub(/[[:space:]]*$/,  "", $3);
   sub(/[[:space:]]+/,  OFS, $3)
   print column_name,$3;
}

Input file (from your posts in differents forums...) :

Code:

$ cat base_compare.txt
______________________________________
            || Base Compare
dept_nub    || cal1 col1
            || _EXIT_DT _EXIT_DT
            ||
_________   || ___________________________
   41041    || 17303 5
   41042    || 17303 0

values for the columns
______________________________________
            || Base Compare
dept_nub    || rate_hi rate_hi
            ||
_________   || __________________________
l0510210    || 100.00 34
   51031    || 17.0 21
  510410    || 17303 0
_______________________________________
            || Base Compare
Ln_numbr    || FNL_PIPLN FNL_PIPLN
            || _EXIT_DT _EXIT_DT
___________ || _________ _________
   41041    || 17303 5
   41042    || 17303 0
   41043    || 17303 34
   41045    || 17303 11
   41046    || 17303 12
NOTE: The MAXPRINT=10 printing limre values will be printed for thisit has been
______________________________________
            || Base Compare
Ln_numbr    || FNL_PIPLN FNL_PIPLN
            ||
___________ || _________ _________
L0051041044 || 100.00 5
L0051041044 || 17.0 0
L0051041044 || 17303 .
L0051041044 || 23.03 11
L0051041044 || 123.0 12
$

Output:

Code:

$ awk -f extract.awk base_compare.txt
cal1_EXIT_DT,17303,5
cal1_EXIT_DT,17303,0
rate_hi,100.00,34
rate_hi,17.0,21
rate_hi,17303,0
FNL_PIPLN_EXIT_DT,17303,5
FNL_PIPLN_EXIT_DT,17303,0
FNL_PIPLN_EXIT_DT,17303,34
FNL_PIPLN_EXIT_DT,17303,11
FNL_PIPLN_EXIT_DT,17303,12
FNL_PIPLN,100.00,5
FNL_PIPLN,17.0,0
FNL_PIPLN,17303,.
FNL_PIPLN,23.03,11
FNL_PIPLN,123.0,12
$

Jean-Pierre.

Thank you very much for your time Jean-Pierre,
actually input file format little bit chaged ,i have tested your scripts works fine but new format file does n't work ,please take look at the new file format below.

|| Base Compare
key_NUM || FNL_PIPLN FNL_PIPLN Diff. % Diff
|| _EXIT_DT _EXIT_DT
___________ || _________ _________ _________ _________
||
L0051041044 || 17303 . . .
L0053125829 || 17303 . . .
L0053855466 || 17303 . . .
L0061072864 || 17303 . . .
L0061288205 || 17303 17103 . .
L0062343827 || 17303 17203 . .
L0062526348 || 17303 23201 . .
L0063725295 || 17303 . . .
L0064004237 || 17303 . . .
L0064723026 || 17303 . . .
|| Base Compare
key_NUM || INIT_WHSE INIT_WHSE Diff. % Diff
|| _AMT _AMT
___________ || _________ _________ _________ _________
||
L0051041044 || 100.2340 12 . .
L0053125829 || 99.9700 . . .
L0053855466 || 98.2790 . . .
L0061072864 || 99.9990 . . .
L0061288205 || 99.1050 134 . .
L0062343827 || 98.5080 . . .
L0062526348 || 100.2340 . . .
L0063725295 || 98.9560 . . .
L0064004237 || 98.9560 . . .
L0064723026 || 99.2930 213 . .
|| Base Compare
key_NUM || FNL_PIPLN FNL_PIPLN Diff. % Diff
|| _AMT _AMT
___________ || _________ _________ _________ _________
||
L0051041044 || 100.2340 . . .
L0053125829 || 99.9700 . . .
L0053855466 || 98.2790 . . .
|| Base Value Compare Value
key_Num || FNL_PIPLN_EXIT_RSN_C FNL_PIPLN_EXIT_RSN_C
|| D D
___________ || _ _
||
L0051041044 || C
L0053125829 || C
L0053855466 || C
L0061072864 || C
L0061288205 || C
L0062343827 || C
L0062526348 || C
L0063725295 || C
L0064004237 || C
L0064723026 || C

I have modified the awk program:

Code:

#!/usr/bin/awk -f
# Awk File: extract.awk

BEGIN {
   FS  = "|";
   OFS = ",";
}

(/Base Compare/),(NF==3 && $1 ~ /^_+ *$/) {
   if (/Base Compare/) {
      column_name = "";
      next;
   }
   if ($3 ~ /^ *__+/)        next;
   sub(/^[[:space:]]*/,  "", $3);
   sub(/[[:space:]]+.*/, "", $3)
   column_name = column_name $3
   next;
}
NF == 3 {
   sub(/^[[:space:]]*/,  "", $3);
   if ($3 == "") next;
   split($3, values, /[[:space:]]+/);
   print column_name,values[1],values[2];
}

Output:

Code:

FNL_PIPLN_EXIT_DT,17303,.
FNL_PIPLN_EXIT_DT,17303,.
FNL_PIPLN_EXIT_DT,17303,.
FNL_PIPLN_EXIT_DT,17303,.
FNL_PIPLN_EXIT_DT,17303,17103
FNL_PIPLN_EXIT_DT,17303,17203
FNL_PIPLN_EXIT_DT,17303,23201
FNL_PIPLN_EXIT_DT,17303,.
FNL_PIPLN_EXIT_DT,17303,.
FNL_PIPLN_EXIT_DT,17303,.
INIT_WHSE_AMT,100.2340,12
INIT_WHSE_AMT,99.9700,.
INIT_WHSE_AMT,98.2790,.
INIT_WHSE_AMT,99.9990,.
INIT_WHSE_AMT,99.1050,134
INIT_WHSE_AMT,98.5080,.
INIT_WHSE_AMT,100.2340,.
INIT_WHSE_AMT,98.9560,.
INIT_WHSE_AMT,98.9560,.
INIT_WHSE_AMT,99.2930,213

Jean-Pierre.

Thank you.

I'm not getting the result as we expected ,below is is the output i'm getting.

,FNL_PIPLN,FNL_PIPLN
,_EXIT_DT,_EXIT_DT
,_________,_________
,17303,.
,17303,.
,17303,.
,17303,.
,17303,17103
,17303,17203
,17303,23201
,17303,.
,17303,.
,17303,.
INIT_WHSE_AMT,100.2340,12