Shell Programming and Scripting

If the file is not separated by tab space then you have to give delimiter
cut -d" " -f1 jam2.txt > one.txt

my requirement got slightly changed now
problem is like : I have a look up file which contain the fixed
e.g

T0011.csv (Look up file)
--------------------------
col1,col2,col3,col4,col5,col6,col7,col8,col9

I have client file which conatin column

T0011.csv (Same as look up file name but in diff path i.e in srcFile folder)
----------------------------------------------------------------
col4 col6
510 erre
510 tru64
510 xxxx


------------Final file should be-----
T0011.csv
-----------------------
col1 col2 col3 col4 col5 col6 col7 col8 col9
510 erre
510 tru64
510 xxxx


here the only change i need is the script should look the client file column in lookup file
it should insert the data of the client file to final table which actually conain all the column of look up file.
here clint file contain col4 and col6 so it should insert the data in the col4 and col6 in sequence as client did not supply the rest of the column all other column should have value blank.

Please assist me urgent !

jambesh is there any posibility that data file may have columns at random sequence like

Code:

col6      col4

or will be in the sequence like col4 col6

Yes Dhruv Data file can be in any order but final file should be according to the lookup sequence order and if data file contain c3,c1 and look up file contain c1,c2,c3,c4,c5,c6
then final file should be c1,c2,c3,c4,c5,c6 column but c2,c4,c5,c6 should conatin blank and c1 and c3 column contain data from client data.

------

Paste command has limitation of pasting only 12 file max to a singler file.
if a lookupfile has more then 12 column then it is throwing error too many argument or bad argumnet ..
how to come around this situation ??
paste -d| temdata* > final_data
here if there is more then 12 tempdata file ..paste will fail.

How many columns lookup file will be having?what i want to ask is if we know the the number of columns lookup file will be having we can work on paste command.

can we write one script like join_all which can pick up n number of file and join the column of each file in sequence ??
each file having one column it could be all space or data column.
if we can do that then this can be short out

A possible solution using awk:

Code:

#
# Lookup file, first line 
#
NR==1 {
   LookupColsCount = split($0, LookupCols, /,/);
   FinalHeader     = $0;
   gsub(/,/, OFS, FinalHeader);
   next;
}

#
# Client file, first line
#
FNR == 1 && FNR != NR {
   ClientColsCount = NF;
   for (i=1; i<=NF; i++) 
      ClientCols[$i] = i;

   FinalColsCount = LookupColsCount;
   for (i=1; i<=LookupColsCount; i++) {
      col_id = LookupCols[i];
      if (col_id in ClientCols)
         FinalCols[i] = ClientCols[col_id];
      else 
         FinalCols[i] = 0;
   }

   print FinalHeader;
   next;
}

#
# Client file, datas
#
FNR != NR {
   FinalLine = "";
   for (i=1; i<=FinalColsCount; i++) {
      if (i > 1) FinalLine = FinalLine OFS;
      col_num = FinalCols[i];
      if (col_num != 0)
         FinalLine = FinalLine $col_num;
   }
   print FinalLine;
}

Execute this awk script with the lookup and client files as input.
You can choose the Output Field Separator with the -v option (the default value is space).
In the following example, OFS is set to '|' :

Code:

awk -v OFS='|' -f script.awk  T0011.csv srcFile/T0011.csv

The output is

Code:

col1|col2|col3|col4|col5|col6|col7|col8|col9
|||510||erre|||
|||510||tru64|||
|||510||xxxx|||

Jean-Pierre.