Shell Programming and Scripting

SAMPLE    DERIVED    ANCESTRAL
Sample1    14352    0
Sample2    14352    0
Sample3    14352    0
Sample4    9880    4472
Sample5    9786    4566
Sample6    9846    4506
Sample7    9787    4565
Sample8    9800    4552
Sample9    9764    4588
Sample10    9760    4592
Sample11    9691    4661
Sample12    9798    4554
Sample13    9740    4612

SAMPLE    DERIVED    ANCESTRAL
Sample1    14352    0
Sample2    14352    0
Sample3    14352    0
Sample4    13674    678
Sample5    13749    603
Sample6    13701    651
Sample7    13682    670
Sample8    13677    675
Sample9    13684    668
Sample10    13674    678
Sample11    13642    710
Sample12    13679    673
Sample13    13713    639

SAMPLE    TOTAL DERIVED    TOTAL ANCESTRAL
Sample1    28704    0
Sample2    28704    0
Sample3    28704    0
Sample4    23554    5150
Sample5    23535    5169
Sample6    23547    5157
Sample7    23469    5235
Sample8    23477    5227
Sample9    23448    5256
Sample10    23434    5270
Sample11    23333    5371
Sample12    23477    5227
Sample13    23453    5251

 awk 'BEGIN{print "SAMPLE    TOTAL DERIVED    TOTAL ANCESTRAL"} FNR==NR{a[$1]=$2;b[$1]=$3;next} FNR>1{$2=$1 in a?$2+a[$1]:$2;$3=$1 in b?$3+b[$1]:$3;print}' array1  array2 | column -t

awk '{split($0,F)} getline<f>0 && NR>1{$2+=F[2]; $3+=F[3]}1' f=array1 array2

awk '
  FNR==1 {
    if(NR==1)
      print
    next
  }
  {
    S[FNR]=$1
    D[$1]+=$2
    A[$1]+=$3
  }
  END {
    for(i=2; i<=FNR; i++)
      print S[i], D[S[i]], A[S[i]]
  }
' array1 array2 ... arrayn

awk '
BEGIN   {FMT = "%-13s%-17s%-17s\n"
         printf FMT, "SAMPLE", "TOTAL DERIVED", "TOTAL ANCESTRAL"
        }
FNR > 1 {SEQ[FNR]  = $1
         SUMD[$1] += $2
         SUMA[$1] += $3
        }
END     {for (i=2; i<=FNR; i++) printf FMT, SEQ[i], SUMD[SEQ[i]], SUMA[SEQ[i]]
        }
'  array[12]
SAMPLE       TOTAL DERIVED    TOTAL ANCESTRAL  
Sample1      28704            0                
Sample2      28704            0                
Sample3      28704            0                
Sample4      23554            5150             
Sample5      23535            5169             
Sample6      23547            5157             
Sample7      23469            5235             
Sample8      23477            5227             
Sample9      23448            5256             
Sample10     23434            5270             
Sample11     23333            5371             
Sample12     23477            5227             
Sample13     23453            5251

awk '	# Invoke awk and start script to be run by awk.
BEGIN	{# Before any lines are read from any input file, set the format string
	 # to be used by all print statements in this script and print the output
	 # header line.
	 FMT = "%-13s%-17s%-17s\n"
	 printf FMT, "SAMPLE", "TOTAL DERIVED", "TOTAL ANCESTRAL"
	}
FNR > 1	{# For all lines in each input file except the header line, save the
	 # sample name associated with that input line and accumulate the derived
	 # and ancestral values associated with that sample name.
	 SEQ[FNR]  = $1
	 SUMD[$1] += $2
	 SUMA[$1] += $3
	}
END	{# After all input files have been processed, for each line found in the
	 # last input file, print the sample name and the accumulated derived
	 # and ancestral totals.
	 for (i=2; i<=FNR; i++) printf FMT, SEQ[i], SUMD[SEQ[i]], SUMA[SEQ[i]]
	}
' array[12]	# End the awk script and list of files to be processed.