Shell Programming and Scripting

What I'm trying to do is, using awk, loading the log file into an array matching column 2, counting the match and finding the first occurance and last occurance of column 1 being it a date.

08052006:AAA
08052006:AAA
08052006:BBB
09052006:AAA
15052006:BBB
11052006:CCC
19052006:CCC
15052006:BBB
20052006:CCC

This is the output I'm trying to achieve:

ID :Count:First Occurance:Last Occurance
AAA:3 :08052006 :09052006
BBB:3 :08052006 :15052006
CCC:3 :11052006 :20052006

I've managed to produce the first two columns of output (I guess that's the easy part), but I just can't work out how to print the first date occurance and the last

Can anyone give me some pointers, please?

show what you have so far, pls

Also when you say 'first occurance'.... do you mean first occurance in the file OR being numerically first [08052006 occuring before 08062006]?

I could post what I've got so far, but the format of the log file is totally different from my example.

What I mean by first and last occurance is the earliest date and the last date an entry was made in the log file for that particular ID.

Okay...did a quick and cut down version of what I have using the example I gave earlier:

/usr/xpg4/bin/awk '{
id_arr[$2]++;
id_dat[$2]=$1;

} END {
for ( x in id_arr ) {
printf "%s:%s:%s:%s\n",x,id_arr[x],id_dat[1],id_dat[NR]
}
}' FS=: test

test file contains:
08052006:AAA
08052006:AAA
08052006:BBB
09052006:AAA
15052006:BBB
11052006:CCC
19052006:CCC
15052006:BBB
20052006:CCC

I thought using id_dat[1],id_dat[NR] would give me the first/earliest date and the last/latest log entry (sorry the log file is sorted in date order)

Bu my output is:
CCC:3::
BBB:3::
AAA:3::

try this one:

Code:

BEGIN {
  FS=OFS=":"
}

{
   id[$2]++
   if ( !($2 in first)) first[$2] = $1
   last[$2]=$1
}
END {
  for(i in id)
    print i, id[i], first[i], last[i]
}

You're a Genius....

Talk about making things look easy.

Thanks very much