Shell Programming and Scripting

awk -F'"[]},:]* *"*' -v RS='{' '
# Function to extract the portion of the data associated with the Alignments
# tag that is to be printed.
function pA(arg,	string) {
	string = arg
	sub(/_R_.*/, "", string)
	return string
}
{	for(i = 2; i < NF - 1; i++) {
		# Look for a "path" entry with the desired "plugin" value.
		if($i == "path") {
			if($(i + 2) == "plugin" &&
			   $(i + 3) == "/rundb/api/v1/plugin/49/") {
				# Set found flag to indicate that we have found
				# a path to be processed.
				found = 1

				# Print the selected path.
				print (u = $(i+1)) "    -- path from " FILENAME

				# Grab the "_user_[^_]*" string from the
				# selected path.
				sub(/.*_user_/, "", u)
				sub(/_.*/, "", u)
				sub(/^/, "user_", u)

				# Skip next 4 fields.
				i += 3
			}
			continue
		}
		if(found == 1) {
			if($i == "Aligned Reads" && index($(i + 1), u)) {
				# We found an Aligned Reads element with the
				# correct user.  Print it, set found to
				# indicate that we have found both a path and
				# an Aligned Reads, and skip over next field.
				print $(i+1) "    -- Aligned Reads from " \
				    FILENAME
				found = 2
				i++
			}
			continue
		}
		if(found == 2)
			if($i == "Alignments")
				print pA($(i+1)) "    -- Alignments from " \
				    FILENAME
			else if($i  == "Sample Name")
				print $(i+1) "    -- Sample Name from " FILENAME
			else if($i == "Aligned Reads")
				# We have found a new Aligned Reads, clear the
				# found flag until we find another matching
				# path.
				found = 0
	}
}' index.html

/results/analysis/output/Home/Auto_user_S5-00580-4-Medexome_65_028/plugin_out/FileExporter_out.52    -- path from index.html
R_2016_09_01_10_24_52_user_S5-00580-4-Medexome    -- Aligned Reads from index.html
IonXpress_004    -- Alignments from index.html
MEV42    -- Sample Name from index.html
IonXpress_005    -- Alignments from index.html
MEV43    -- Sample Name from index.html
IonXpress_006    -- Alignments from index.html
MEV44    -- Sample Name from index.html