Shell Programming and Scripting

Study	Point	Value
1	p1	value1
1	p2	value2
1	p3	value1
1	p4	value3
1	p5	value3
2	p2	value1
2	p4	value1
3	p1	value1
3	p5	value5
3	p3	value1
4	p2	value1
4	p4	value5

Point1	Point2	#StudiesWhereValuesAreDifferentForThisPair
p1	p2	1
p1	p4	1
p1	p5	2
p2	p3	1
p2	p4	2
p2	p5	1
p3	p4	1
p3	p5	2
p4	p5	1

awk '{sp[$1 FS $2]=$3;s[$1];p[$2];next }END { for(ss in s) { for (p1s in p) { for (p2s in p)   { if (p1s !=p2s) { print ss,p1s,p2s,sp[ss FS p1s],sp[ss FS p2s] } }}}}'  | awk 'NF==5' | awk '$4!=$5' dataset

awk '
$1+0 {a[$2]=$2; b[$2,c[$2]++]=$3}                                        # load variable names array, load pairs array
END {
   for (i in a) {
      for (j in a) {
         if (i != j) {
            for (k=0; k<c[i]; k++) {
               if (b[i,k] && b[j,k] && (b[i,k] != b[j,k])) {
                  out[i,j]++;                                            # count pair mismatches for existing pairs
               }
            }
         }
      }
   }
   print "Point1\tPoint2\t#StudiesWhereValuesAreDifferentForThisPair";   # print header
   for (i in a) {
      for (j in a) {
         if (out[i,j] && ! p[j,i] && ! p[i,j]) {                         # for non repeat pairs output
            print i "\t" j "\t" out[i,j];                                # print pair mismatch counts
            p[j,i]=p[i,j]=1;                                             # set pair array printed
         }
      }
   }
}
' infile

awk 'BEGIN{print "Study" OFS "Point" OFS "Value"} NR>1{C[$2];E[$2 OFS 1+C[$2]++]=$3;sub(/[[:alpha:]]/,X,$2);Q=Q>$2+0?Q:$2+0} END{;for(i in C){D[++j]=i};for(i=1;i<=length(D);i++){for(k=i+1;k<=length(D);k++){for(q=1;q<=Q;q++){if(E[D[i] OFS q] != E[D[k] OFS q] && E[D[i] OFS q] && E[D[k] OFS q]){R[D[i] OFS D[k]]++;}}}};for(u in R){print u OFS R[u]}}' OFS="\t"   Input_file

awk 'BEGIN{
           print "Study" OFS "Point" OFS "Value"
          } 
     NR>1 {
           C[$2];
           E[$2 OFS 1+C[$2]++]=$3;
           sub(/[[:alpha:]]/,X,$2);
           Q=Q>$2+0?Q:$2+0
          } 
     END  {
           for(i in C){
                       D[++j]=i
                      };
           for(i=1;i<=length(D);i++){
                                     for(k=i+1;k<=length(D);k++){
                                                                 for(q=1;q<=Q;q++){
                                                                                   if(E[D[i] OFS q] != E[D[k] OFS q] && E[D[i] OFS q] && E[D[k] OFS q]){
                                                                                                                                                        R[D[i] OFS D[k]]++;
                                                                                                                                                                                  }
                                                                                  }
                                                                }
                                    };
           for(u in R){
                       print u OFS R[u]
                      }
           }
    ' OFS="\t"   Input_file

#!/bin/ksh
awk '
BEGIN {	# Before reading 1st line from the input file, set output field
	# separator to <tab> and print heading.
	OFS = "\t"
	print "Point1", "Point2", "Number_of_Studies_with_Different_Values"
}
NR == 1 {
	# Skip over the input file header line.
	next
}
$1 != last {
	# If the 1st field has changed, process all of the lines read for the
	# previous value of the 1st field.
	count()

	# Save the current value of the 1st field.
	last = $1
}
{	# Increment the number of lines seen for this 1st field value and save
	# the point name and the value from the current line.
	p[++n] = $2
	v[n] = $3
}
END {	# Process the last 1st field value.
	count()

	# Print the accumulated results.
	for(i in diffs)
		# Uncomment one and only one of the following lines.
		print i, diffs[i] | "sort"	# use this to sort output
		# print i, diffs[i]		# use this for unsorted output
}
function count(		i, j) {
	# Process the set of lines for a given 1st field value.
	# There are "n" lines in the set.  for each of the 1st "n-1" lines
	# in this set...
	for(i = 1; i < n; i++)
		# for each of the remaining lines in the set...
		for(j = i + 1; j <= n; j++)
			# if the values for those two points are different...
			if(v[i] != v[j])
				# Increment the number of times this pair of
				# points (with the two points sorted by point
				# names) has had different values.
				diffs[(p[i] < p[j]) ?  p[i] OFS p[j] : \
				    p[j] OFS p[i]]++

	# Reset the line counter for the next set.
	n = 0
}' dataset

Point1	Point2	Number_of_Studies_with_Different_Values
p1	p2	1
p1	p4	1
p1	p5	2
p2	p3	1
p2	p4	2
p2	p5	1
p3	p4	1
p3	p5	2

Point1	Point2	Number_of_Studies_with_Different_Values
p3	p4	1
p3	p5	2
p2	p3	1
p2	p4	2
p2	p5	1
p1	p2	1
p1	p4	1
p1	p5	2

Study	Point	Value
1	p1	value1
1	p2	value1
1	p3	value1
1	p4	value1
1	p5	value1
2	p2	value2
2	p4	value2
3	p1	value3
3	p5	value3
3	p3	value3
4	p2	value4
4	p4	value4

Point1	Point2	Number_of_Studies_with_Different_Values

Point1	Point2	#StudiesWhereValuesAreDifferentForThisPair
p1	p2	1
p1	p4	1
p2	p3	1
p2	p5	1
p3	p4	1
p4	p5	1

Study Point Value
p4	p5	1
p3	p4	1
p2	p3	1
p2	p5	1
p1	p2	1
p1	p4	1