Shell Programming and Scripting

can someone help me debug why this isn't working:

Code:

awk 'NR>1 {
                                                                a["C00"] += gsub("(^| )C00( |$)", "&")
                                                        } END {
                                                                for (i in a)
                                                                        printf("%s=%s\n", i, a[i])
                                                        }' test.log

test.log:

Code:

prudb05,C000464262,T7845491
prudb06,C000464632,T784931
prubb01,C0004634632,T783595
prusb02,C000461462,T7859665

when i run it, it reports wrong numbers. its always zero. I want it to tell me how many lines it found containing the string "C00" (that's C zero zero not the letter O).

the output should be something like this:

Code:

C00=3

System this must be able to run on: all unix systems - linux, sunos, hpux, aix.

Hello SkySmart,

Could you please try following and letme know if this helps you then.(I haven't tested it though.)

Code:

awk '{count=gsub("COO",X,$0);print "Line " NR " contains " count " number of occurances of COO"}' Input_file

Thanks,
R. Singh

Code:

awk '/C00/ {++c} END{print "C00="c}' test.log

You built a nice, complex regex that matches "C00" surrounded by spaces OR at EOL OR at BOL. None of these conditions are TRUE for your file, so no surprise you get a zero count. Try modifying either your regex or your input file.

Aia's nice and simple approach works well for single occurrences of "C00" per line, while the gsub will count all "C00" s in a line.

Your code is looking for the number of times C00 preceded by the start of the line or a <space> and followed by a <space> or the end of the line appears on lines after the 1st line in a file named test.log. (And, those conditions are not met on any line in your sample data.)

You didn't say anything about skipping the first input line in your description, but unless you skip one of the input lines, the number of lines containing the string C00 should be 4; not 3.

Since you're using an array in your code, I will make the (hopefully not too wild) assumption that you also want to search for other strings on the same invocation of your script.

To meet your stated requirement: "tell me how many lines it found containing the string C00" and expand that to also tell you how many lines it found containing the string 463 (note how many lines contain; not how many times does the string appear), you could try something more like:

Code:

printf '%s\n' "C00" "463" | awk '
FNR == NR {
	string[++cnt] = $0
	next
}
{	for(i = 1; i <= cnt; i++)
		if($0 ~ string[i])
			a[string[i]]++
}
END {	for(i = 1; i <= cnt; i++)
		printf("%s=%d\n", string[i], a[string[i]])
}' - test.log

Of course, instead of using printf and reading the list of strings into your script from standard input, you could define the strings in another file or hardcode them into a BEGIN clause in an awk script.

With the sample data you provided in a file named test.log, the above script produces the output:

Code:

C00=4
463=2

If your requirements are not what you stated before and you can't figure out how to modify the code above to get what you need, please restate your requirements clearly and provide sample input and output that match your requirements.

The same awk code should work on any recent system that has awk, but on a Solaris/SunOS system, you'll need to use /usr/xpg4/bin/awk or nawk instead of the default awk.

so the command i posted was being used to search for multiple patterns in big files. it's suppose to be more efficient. and it was working up until recently. i'm trying to figure out what went wrong.