Shell Programming and Scripting

awk '
FNR==NR         {R[$1".log"]=$2               ######### FNR==NR will be TRUE whenever first file will be read as value of FNR will be reset whenever a next file is being read. Creating an array named R with index $1 and ".log" whose value is $2(second field).
                 next                         ######### After executing above statement don't perform any further actions and go to next line.
                }
$2 in R         {REP = R[$2]                  ######### This will be executed while second file is being read and $2 in R means if second field is present in array R then keep the value of REP to R[$2]
                }
$1 == "$Param4" {if (REP) $2 = REP            ######### if $1=="$Param4" then if(REP) means check if value of variable named REP is NOT NULL make $2's value equal to variable REP.
                }
$1 == "$Param5" {if (REP) $2 = REP            ######### if $1=="$Param5" then if(REP) means check if value of variable named REP is NOT NULL make $2's value equal to variable REP.
                 REP = ""                     #########  Then nullify value of REP.
                }
1                                             ######### awk works on theme of conditions and actions. Here we are making condition TRUE by mentioning 1 and no action is being mentioned so default action will be done which is printing the line.
' FS="," file1 FS="=" OFS="=" file2           ######### setting value of Field seprator to comma while file1 is being read and setting value of Field seprator and Output field seprator to = for file2.