Shell Programming and Scripting

awk -F\| '
FNR == NR       {HD[NR] = $0
                 MXCOL = NR
                 next
                }
FNR == 1        {for (n=1; n<=NF; n++)
                   for (h in HD)  if ($n == HD[h])      {{COL[h] = n
                                                         break
                                                        }
                }
                {DL = ""
                 for (c=1; c<=MXCOL; c++) if (COL[c])   {printf "%s%s", DL, $(COL[c])
                                                         DL = FS
                                                        }
                 printf "\n"
                }
' ctrl source
ename|eid|esal
peter|10|$2000
shaun|11|$1000

awk '	# Name interpreter to be used and start the script to be run.
BEGIN {	# Set input and output field separators before we read any input files.
	FS = OFS = "|"
}
FNR == NR {
	# When the number of records read from the current file (FNR) is the
	# same as the number of records read from all files (NR), we are reading
	# data from the control file.
	# For each line read, set the heading data array indexed by the desired
	# heading data to the output field position for this heading.  (The
	# output field position is also the current number of lines read from
	# the control file.)
	hd[$0] = ++hc
	# Skip to next input line without processing later actions in this
	# script.
	next
}
FNR == 1 {
	# When we read the 1st line of the data file, look at each heading...
	for(i = 1; i <= NF; i++)
		# If the heading is an index in the hd[] array...
		if($i in hd)
			# Set the output field order array indexed by the
			# desired output order to the input field number to be
			# printed in that field.
			of[hd[$i]] = i
}
{	# For all lines in the data file print the desired input fields in the
	# order in which they are supposed to appear in the output file...
	for(i = 1; i <= hc; i++)
		# Print the desired field and the output field separator (when
		# the loop variable does not indicate the last time through the
		# loop) or the output record separator (if the loop variable
		# does indicate the last time through the loop).
		printf("%s%s", $of[i], i == hc ? ORS : OFS)
}' ctrl2 source	# End the script and name the two input files.

#!/usr/bin/env bash

# @(#) s1	Demonstrate extraction from CSV file, csvtool.

# Utility functions: print-as-echo, print-line-with-visual-space, debug.
# export PATH="/usr/local/bin:/usr/bin:/bin"
LC_ALL=C ; LANG=C ; export LC_ALL LANG
pe() { for _i;do printf "%s" "$_i";done; printf "\n"; }
pl() { pe;pe "-----" ;pe "$*"; }
db() { ( printf " db, ";for _i;do printf "%s" "$_i";done;printf "\n" ) >&2 ; }
db() { : ; }
C=$HOME/bin/context && [ -f $C ] && $C csvtool

FILE1=data1
FILE2=data2

pl " Input source file $FILE1:"
cat $FILE1

pl " Input control file $FILE2:"
cat $FILE2

pl " Expected output:"
cat expected-output.txt

pl " Transformed control file:"
tr '\n' ',' < $FILE2 |
sed 's/,$//' |
tee data3

# Duplicate first line, so that names are transferred.
sed -n -e '1p' -e '1,$p' $FILE1 > f1

pl " Results:"
csvtool namedcol "$( cat data3 )" -t '|' -u '|' f1

exit 0

$ ./s1

Environment: LC_ALL = C, LANG = C
(Versions displayed with local utility "version")
OS, ker|rel, machine: Linux, 2.6.26-2-amd64, x86_64
Distribution        : Debian 5.0.8 (lenny, workstation) 
bash GNU bash 3.2.39
csvtool - ( /usr/bin/csvtool, 2008-05-22 )

-----
 Input source file data1:
ename|eid|emanger|esal|ecity|deptid|deptname
peter|10|larry|$2000|melbourne|20|electronics
shaun|11|Peter|$1000|sydney|20|electronics

-----
 Input control file data2:
ename
eid
esal
ecity

-----
 Expected output:
ename|eid|esal|ecity
peter|10|$2000|melbourne
shaun|11|$1000|sydney

-----
 Transformed control file:
ename,eid,esal,ecity
-----
 Results:
ename|eid|esal|ecity
peter|10|$2000|melbourne
shaun|11|$1000|sydney

Name        : ocaml-csv
Arch        : x86_64
Version     : 1.1.7
Release     : 6.2.el6
Size        : 149 k
Repo        : base
Summary     : OCaml library for reading and writing CSV files
URL         : http://merjis.com/developers/csv
License     : LGPLv2+
Description : This OCaml library can read and write CSV files, including all
            : extensions used by Excel - eg. quotes, newlines, 8 bit characters
            : in fields, quote-0 etc.
            : 
            : The library comes with a handy command line tool called csvtool
            : for handling CSV files from shell scripts.