Shell Programming and Scripting

Hi guys,

the command is

Code:

 echo "Online Memory                              : 32768 MB" | sed 's/.*\([0-9]+\).*/\1/'

I would expect it to print 32768, it cuts off any character to the first digit, then gets all digits in 1, cuts off the rest after the digits, and should print 32768, instead it prints everything again


of course in this case, the easiest thing would be

Code:

echo "Online Memory                              : 32768 MB" | sed 's/[^0-9]//g'

but I'm just curious why the first command doesn't work

thanks in advance

funksen

Strange. It obviously doesn't match the pattern, so prints without substitution. It doesn't match [[:digit:]]either, nor any repetition factor.
It would match " [0-9]* " , i.e. surrounded by spaces, but not with a + sign...

thx, the problem is, instead of "*", the "+" has to be escaped "\+" in sed, didn't know this

also .* would match the digits as well, so if I don't know whats before and behind the digits, I would have to use this statement I guess

Code:

 sed 's/[^0-9]*\([0-9]\+\).*/\1/'

Actually \+ is a GNU extension.

In any sed (including GNU sed) one could use:

Code:

sed 's/[^0-9]*\([0-9]\{1,\}\).*/\1/'

or

Code:

sed 's/[^0-9]*\([0-9][0-9]*\).*/\1/'

--
In GNU sed one could use the -r option:

Code:

sed -r 's/[^0-9]*([0-9]+).*/\1/'

thank you Scrutinizer, never thought of using the curly bracket syntax, seems the right thing to go here, expect of the obvious

Code:

sed 's/[^0-9]//g'