Shell Programming and Scripting

$ cat xml.awk

BEGIN {
        FS=">"; OFS=">";
        RS="<"; ORS="<"
}

# These should be special variables for match() but aren't.
function rbefore(STR)   { return(substr(STR, N, RSTART-1)); }# before match
function rmid(STR)      { return(substr(STR, RSTART, 1)); }  # First char match
function rall(STR)      { return(substr(STR, RSTART, RLENGTH)); }# Entire match
function rafter(STR)    { return(substr(STR, RSTART+RLENGTH)); }# after match

function aquote(OUT, A, PFIX, TA) { # Turns Q SUBSEP R into A[PFIX":"Q]=R
        if(OUT)
        {
                if(PFIX) PFIX=PFIX":"
                split(OUT, TA, SUBSEP);
                A[toupper(PFIX) toupper(TA[1])]=TA[2];
        }

        return("");
}

# Intended to be less stupid about quoted text in XML/HTML.
# Splits a='b' c='d' e='f' into A[PFIX":"a]=b, A[PFIX":"c]=d, etc.
function qsplit(STR, A, PFIX, X, OUT) {
        while(STR && match(STR, /([ \n\t]+)|[\x27\x22=]/))
        {
                OUT = OUT rbefore(STR);
                RMID=rmid(STR);

                if((RMID == "'") || (RMID == "\""))     # Quote characters
                {
                        if(!Q)          Q=RMID;         # Begin quote section
                        else if(Q == RMID)      Q="";   # End quote section
                        else                    OUT = OUT RMID; # Quoted quote
                } else if(RMID == "=") {
                        if(Q)   OUT=OUT RMID; else OUT=OUT SUBSEP;
                } else if((RMID=="\r")||(RMID=="\n")||(RMID=="\t")||(RMID==" ")) {
                        if(Q)   OUT = OUT rall(STR); # Literal quoted whitespace
                        else    OUT = aquote(OUT, A, PFIX); # Unquoted WS, next block
                }
                STR=rafter(STR); # Strip off the text we've processed already.
        }

        aquote(OUT STR, A, PFIX); # Process any text we haven't already.
}


{ SPEC=0 ; TAG="" }

NR==1 {
        if(ORS == RS) print;
        next } # The first "line" is blank when RS=<

/^[!?]/ { SPEC=1    }   # XML specification junk

# Handle open-tags
match($1, /^[^\/ \r\n\t>]+/) {
        TAG=substr(toupper($1), RSTART, RLENGTH);
        if((!SPEC) && !($1 ~ /\/$/))
        {
                TAGS=TAG "%" TAGS;
                DEP++;
                LTAGS=TAGS
        }

        for(X in ARGS) delete ARGS[X];

        qsplit(rafter($1), ARGS);
}

# Handle close-tags
(!SPEC) && /^[\/]/ {
        sub(/^\//, "", $1);
        LTAGS=TAGS
#        sub("^.*" toupper($1) "%", "", TAGS);
        sub("^" toupper($1) "%", "", TAGS);
        $1="/"$1
        DEP=split(TAGS, TA, "%")-1;
        if(DEP < 0) DEP=0;
}

$

$ awk -f xml.awk -e '(TAGS ~ /^TEXT/) {
        printf("{{Text_ID=%s}}{{From=%s}}\n",ARGS["TEXT_ID"],ARGS["FROM"]);
        N=gsub(/\n/, "")+1;
        for(M=1; M<=N; M++) { RS="\n"; getline < "altinput.txt" ; RS="<" ; print } ; print "<ENDTEXT>" }' ORS="\n" OFS=" " text.xml

{{Text_ID=10155645315851111_10155645333076543}}{{From=460350337461111}}
This is the first text
<ENDTEXT>
{{Text_ID=10155645315851111_10155645317023456}}{{From=1626711840902323}}
This is the second text
<ENDTEXT>
{{Text_ID=10155645315851111_10155645320006543}}{{From=1481727095384343}}
This is the third text
If counted
GOT IT... ����
<ENDTEXT>
{{Text_ID=}}{{From=}}
This is the fourth text ........ This is different.
<ENDTEXT>

$

{{Text_ID=}}{{From=}}
This is the fourth text ........ This is different.
<ENDTEXT>

{{Text_ID=10155645315851111_10155645326222345}}{{FROM=411021195696789}}
This is the fourth text ........ This is different.
<ENDTEXT>

$ awk -f xml.awk -e '(TAGS ~ /^TEXT/) {
        printf("{{Text_ID=%s}}{{From=%s}}\n",ARGS["TEXT_ID"],ARGS["FROM"]);
        NN=$0 ; NN=gsub(/\n/, "",NN)+1;
        for(MM=1; MM<=NN; MM++) { RS="\n"; getline < "altinput.txt" ; RS="<" ; print } ; print "<ENDTEXT>" }' ORS="\n" OFS=" " text.xml
{{Text_ID=10155645315851111_10155645333076543}}{{From=460350337461111}}
This is the first text
<ENDTEXT>
{{Text_ID=10155645315851111_10155645317023456}}{{From=1626711840902323}}
This is the second text
<ENDTEXT>
{{Text_ID=10155645315851111_10155645320006543}}{{From=1481727095384343}}
This is the third text
If counted
GOT IT... ����
<ENDTEXT>
{{Text_ID=10155645315851111_10155645326222345}}{{From=411021195696789}}
This is the fourth text ........ This is different.
<ENDTEXT>

$