Shell Programming and Scripting

file:

Code:

1
2
3
4
5
6
7
8
9
10

code:

Code:

awk 'END{if( < NR/2) {print $0}}' file

The above has some error

Output needed:

Code:

1
2
3
4
5

Can some one help me to get the above output.

Try:

Code:

awk '{x[++xc] = $0}END{for(i = 1; i <= xc/2; i++) print x[i]}' file

but, of course, this won't print a half line if the number of input lines is odd.

Roozo, your condition

Code:

if( < NR/2)

is incomplete.

Try this:

Code:

awk -v totrecs=$(wc -l < file) ' {if (NR <= totrecs/2) {print $0}}' file
1
2
3
4
5

Hi, another awk solution (tested with gnu awk):

Code:

awk -F"\n" -vOFS="\n" '{X=X$0"\n"}END{$0=X;NF=NR/2;print}' file

Although this version reads the file twice it could turn out to be more efficient when dealing with large files or limited resource systems, it doesn't involve copying large amounts of data into memory.

Code:

awk 'FNR==NR{lines++;next}FNR<=lines/2' file file

Good point Chubler_XL: And, if the file is relatively large, you can speed it up by only reading the file one and a half times instead of twice:

Code:

awk 'FNR==NR{lines++;next}FNR>lines/2{exit}1' file file

With a ten line file, my original proposal is probably faster. With a 1Gb file, this will consume much less memory while it is running. With a 1Tb file, awk may not be able to allocate enough resources to do the job the 1st way while this way should work just fine.

Only the original poster knows how much data is being processed, how much memory and swap space are available, what type of processor, ... and can choose what will work best in his or her environment.

Middle ground, using half the memory, reading file once, without an END section:

Code:

awk '{i=NR/2} i in A{print A[i]; delete A[i]}{A[NR]=$0}' file

or

Code:

awk '{A[NR]=$0} !(NR%2){print A[NR/2]; delete A[NR/2]}' file

---
Probably this is the most efficient :

Code:

awk -v h=$(echo $(wc -l <file)) 'NR>h/2{exit}1' file