Shell Programming and Scripting

Hello folks, having a new problem with an old solution I previously had working, but think i'm missing something here.

File1:

Code:

900001093|HAMU1|SUDO_ALIAS
100100361|IAM_IDS|SUDO_ALIAS
100100361|AMPF|SUDO_ALIAS

File2:

Code:

ABC123456|Cust1|900001093|myemail@here.com|Jane Smith|Win1|hamu1
DEF234567|Cust2|100100361|hisemail@there.com|John Doe|UX1|iam_ids
DEF234567|Cust2|100100361|hisemail@there.com|John Doe|UX1|ampf

This is my code I am trying to use:

Code:

awk -F\| 'FNR==NR {(a[$1] = $3) && (a[$2] = toupper($7));next} {print a[$1,$2,$3], $4, $5}' File1 File2

What I am trying to do is match fields 1,2 of File1 against fields 3,7 of File2, and print all of File1 fields, and fields 4,5 of File2 only. However, what I am getting is only fields 4,5 out of File2 with space as a field separator.

Expected output:

Code:

900001093|HAMU1|SUDO_ALIAS|myemail@here.com|Jane Smith
100100361|IAM_IDS|SUDO_ALIAS|hisemail@there.com|John Doe
100100361|AMPF|SUDO_ALIAS |hisemail@there.com|John Doe

Big problem #1: You are using "field 7" in the 'NR==FNR' code block which gets run for file 1 only -- that file has no "field 7". All that code block should be doing is loading file 1, it knows nothing about file 2 yet.

The other code block deals with the contents of file 2. What it's supposed to do is retrieve the matching contents of the array and print it all like you wanted.

Big problem #2: You are assigning A[$1], then assigning A[$2], then expecting output in A[$1,$2,$3]. Doesn't work that way. If you set A["stuff"] to 3, then A["else"] to 4, A["stuff","else"] won't get you anything sensible.

This is because "stuff","else" just becomes a string -- "stuff" SUBSEP "else", where SUBSEP is a special variable which is usually some odd nonprinting ASCII character. This lets awk pretend to have multidimensional arrays while actually just keeping a single index.

So:

Code:

$ awk -F"|" -v OFS="|" 'NR==FNR { A[$1,$2]=$3; next } # Save data

$3 SUBSEP toupper($7) in A { # If the data is found in the array
        print $3, toupper($7), A[$3 SUBSEP toupper($7)], $4, $5;
}' file1 file2

900001093|HAMU1|SUDO_ALIAS|myemail@here.com|Jane Smith
100100361|IAM_IDS|SUDO_ALIAS|hisemail@there.com|John Doe
100100361|AMPF|SUDO_ALIAS|hisemail@there.com|John Doe

$

Oh, and -v OFS="|" controlls what print "A","B","C" does. By default it would print "A B C". By setting it to | it prints "A|B|C".

Thanks Corona688. That solved my problem. And now that I see it in the code, the problem is a bit more obvious. Appreciate the explanation.