Shell Programming and Scripting

Can anyone please assist me?
Condition 1:
if (substr($0,134,1) == "X") , then look for the corresponding matching record(USe Fields - substr($0,2,13),substr($0,136,16),substr($0,114,14)) that has column value 'L' in the same positon and then remove both X and L records.if there are multiple matching L records with the same values in all 3 fields then remove only one L record .
Condition 2:
Incase if there is no corresponding matching record ,then remove only X record.
Condition 3: incase if there are multiple L lines with the same values in all the fields
then we should include all those records in the output file .

Condition 4 : final output contains only L records
sample code:

Code:

awk '
{ if(substr($0,134,1) == "X") {
x[substr($0,2,13),substr($0,136,16),substr($0,114,14)] = $0
} else if(substr($0,134,1) == "L") {
l[substr($0,2,13),substr($0,136,16),substr($0,114,14)] = $0
} else # Print non-L, non-X records.
print
}
END { for(i in x)
if((i in l) || (i in x))
delete l[i]
else
print x[i]
for(i in l)
print l[i]
}' InputFile.txt

InputFile.txt
Desired Output File.txt

Here is a copy of your code with indentation added to make it easier to read and line numbers added for reference in the following notes:

Code:

1 awk '
2 {	if(substr($0,134,1) == "X") {
3		x[substr($0,2,13),substr($0,136,16),substr($0,114,14)] = $0
4	} else if(substr($0,134,1) == "L") {
5		l[substr($0,2,13),substr($0,136,16),substr($0,114,14)] = $0
6	} else # Print non-L, non-X records.
7	print
8 }
9 END {	for(i in x)
10		if((i in l) || (i in x))
11			delete l[i]
12		else
13			print x[i]
14	for(i in l)
15		print l[i]
16}' InputFile.txt

Notes:Please clarify your requirements.

Don,

sorry for the confusion .
I'm facing some issues in my code. My current code is not working as expected.
1) Condition 1 says an X records removes one L record. Line 11 deletes all L records for any matching X record.
Ans: My code deletes all matching L records. I need to delete only one L record . I'm not sure how to handle this?
2) Condition 4 says final output contains only L records; Lines 7 and 13 print non-L records.
Ans: I should print only L records . need to fix this part .
3)Condition 3 says that if there are multiple identical L records, all of them should be printed. Condition 1 says that if there is an X record, a matching L record is to be removed? These conditions conflict with each other? Which one takes precedence.
Ans: There will be cases like X records won't be there, but Multiple identical L records will be there in the file. In this case, i have to print all the L records.
4)Condition 2 is not needed. It restates a subset of the requirements stated by Condition 4.
Ans: you are right
5) question 5,6,7,8 - yes, I have to use substr function.
6)For your given sample data, when the key fields match, the other fields are also identical. Is this always the case? If not, how is your script supposed to decide which one will be deleted when there is an X record with a matching key?
Yes, there will be cases like when the key fields match, the other fields are also identical. we can delete any one of the matching record.
if the key fields are not matching, then print all records.
hope this helps . please let me know if you have any other questions.
thanks for looking into my code.

This seems to do what you want:

Code:

awk '
{	if((rec_type = substr($0,134,1)) == "X") {
		# Increment count of X records for this key.
		xc[substr($0,2,13),substr($0,114,14),substr($0,136,16)]++
	} else if(rec_type == "L") {
		# Increment count of L records for this key, and save this L
		# record..
		l[substr($0,2,13),substr($0,114,14),substr($0,136,16),
			++lc[substr($0,2,13),substr($0,114,14),
				substr($0,136,16)]] = $0
	}
}
END {	# For each key, reduce the count of L records saved for that key by the
	# count of X records found for that key, and then print the earliest L
	# records from the file for the given key.
	for(i in lc) {
		# Reduce L count by X count for key i.
		lc[i] -= xc[i]
		# Print L count L records.
		for(j = 1; j <= lc[i]; j++)
			print l[i,j]
	}
}' InputFile.txt

Don,

Thanks a lot for your help! The code is working as expected. I have tested almost all the scenarios and its perfectly working fine. I'm still testing the code and let you know incase of any issues.