Shell Programming and Scripting

I have 2 file, file1 and file2. file1 has some keys and file2 has keys+some other data. I want to remove the lines from file2,if the key for that line exists in file1.

file1:

Code:

key1
key2

flie2:

Code:

key1,moredata
key2,moredata
key3,moredata

Required output:

Code:

key3,moredata

Thanks

EDIT:
What I have tried:

Code:

awk 'NR==FNR{A[$1];next} {B[$1];next} END {for ( k in B) {if ( ! ( k in A)) { print k}}}' file1 file2

But this just gives the every keys in file2.

try:

Code:

awk 'NR==FNR {a[$0]=$0; next} !a[$1]' file1 FS=, file2

Try

Code:

grep -vffile1 file2

Not knowing what the keys are like, it is a mistake to use !a[$1]. What if one of the keys is 00000? The check should be done using the 'in' operator. Or, instead of storing $0, simply increment the array member so its value is positive or undefined.

Regards,
Alister

---------- Post updated at 11:09 AM ---------- Previous update was at 10:40 AM ----------

I don't think that's a good solution. If the key can appear as part of the data, there can be false positive matches which incorrectly exclude a line. Another possible issue could be regular expression metacharacters in the key.

Regards,
Alister

Code:

$ awk -F, 'FNR==NR{A[$1];next}!($1 in A)' file1 file2
key3,moredata

Combining rdrxt1's suggestion with alister's remark and akshay's suggestion, an alternate version would be:

Code:

awk 'FNR==NR{A[$1]; next}!($1 in A)' file1 FS=, file2

Which would be insensitive to spurious leading/trailing spaces in file1 . This may seem picky, but file1 is more likely to be a file that is edited manually, so space here or there is easily added by accident..

Actually there are leading spaces in file1, when I checked it again. But I am generating file1 using a script, so I can easily remove them.

EDIT:
This seems to be working for me:

Code:

awk 'NR==FNR{A[$1]=$1;next} !($1 in A)' file1 FS=, file2

and this is also working, even though I have leading whitespaces in file1.

Code:

awk 'NR==FNR{A[$1];next} !($1 in A)' file1 FS=, file2

Thanks everyone for you help